Функция _GUICtrlRichEdit_SetParaTabStops

 ↑  ←  Описание функции

_GUICtrlRichEdit_SetParaTabStops

Sets tab stops of paragraphs having selected text or, if none selected, sets it for text inserted at the insertion point

#include <GuiRichEdit.au3>
_GUICtrlRichEdit_SetParaTabStops($hWnd, $sTabStops)

Параметры

$hWnd Дескриптор элемента
$sTabStops A string consisting of groups separated by ; (semicolon). Format of a group:
    absolute position of a tab stop (in space units)
    kind of tab
    l - left tab
    c - center tab
    r - decimal tab
    b - bar tab
    kind of dot leader
    . - dotted leader
    - - dashed leader
    _ - underline leader
    = - double line leader
    t - thick-line leader
    a space - no leader

Возвращаемое значение

Успех:Возвращает True
Ошибка:Возвращает False и устанавливает @error
@error:101 - $hWnd is not a handle
1021 - absolute position of a tab stop missing or invalid
1022 - kind of tab missing or invalid
1023 - kind of tab leader missing or invalid
1024 - attempt to set too many tab stops
@extended contains the tab number (ref 1) in $sTabStops where the error occurred.

Примечания

To reset the tab stops, do _GUICtrlRichEdit_SetParaTabStops($hWnd, "")

To set "space units", call _GUICtrlRichEdit_SetSpaceUnit. Initially inches

To enter a tab into a control, press Ctrl_Tab

См. также

_GUICtrlRichEdit_GetParaTabStops, _GUICtrlRichEdit_SetSpaceUnit, _GUICtrlRichEdit_SetTabStops

См. также

Искать EM_SETCHARFORMAT в библиотеке MSDN

Пример

#include <GuiRichEdit.au3>
#include <GUIConstantsEx.au3>
#include <WindowsConstants.au3>

Global $lblMsg, $hRichEdit

Main()

Func Main()
    Local $hGui, $btnNext, $iStep = 0
    $hGui = GUICreate(StringTrimRight(@ScriptName, 4), 420, 350, -1, -1)
    $hRichEdit = _GUICtrlRichEdit_Create($hGui, 'Это тест.', 10, 10, 400, 220, _
            BitOR($ES_MULTILINE, $WS_VSCROLL, $ES_AUTOVSCROLL))
    $lblMsg = GUICtrlCreateLabel("", 10, 235, 300, 60)
    $btnNext = GUICtrlCreateButton("Далее", 270, 310, 60, 30)
    GUISetState()

    _GUICtrlRichEdit_SetText($hRichEdit, "First paragraph")
    Report("0. Para with default settings")

    While 1
        Switch GUIGetMsg()
            Case $GUI_EVENT_CLOSE
                _GUICtrlRichEdit_Destroy($hRichEdit)
                GUIDelete()
                Exit
            Case $btnNext
                $iStep += 1
                Switch $iStep
                    Case 1
                        _GUICtrlRichEdit_AppendText($hRichEdit, @CR & "Second paragraph")
                        _GUICtrlRichEdit_SetParaTabStops($hRichEdit, ".3l ;1c ;2.5r.")
                        Report("1. TabStops of second paragraph")
                    Case 2
                        _GUICtrlRichEdit_SetSel($hRichEdit, 0, 2)
                        Report("2. Tabstops of first paragraph")
                    Case 3
                        _GUICtrlRichEdit_SetSel($hRichEdit, 10, 26)
                        Report("Tabstops of first paragraph in selection")
                    Case 4
                        _GUICtrlRichEdit_SetParaTabStops($hRichEdit, "2.3r=")
                        Report("3. Change tabstops of both paragraphs")
                    Case 5
                        ; Весь RTF-код сохраняет в файл на Рабочем столе чтобы посмотреть в Word
                        _GUICtrlRichEdit_Deselect($hRichEdit)
                        _GUICtrlRichEdit_StreamToFile($hRichEdit, @DesktopDir & "\gcre.rtf")
                        GUICtrlSetState($btnNext, $GUI_DISABLE)
                EndSwitch
        EndSwitch
    WEnd
EndFunc   ;==>Main

Func Report($sMsg)
    $sMsg &=  @CR & @CR & "Get function returns " & @CR & _GUICtrlRichEdit_GetParaTabStops($hRichEdit)
    GUICtrlSetData($lblMsg, $sMsg)
    ControlFocus($hRichEdit, "", "")
EndFunc   ;==>Report