Функция _GUICtrlRichEdit_SetTabStops

 ↑  ←  Описание функции

_GUICtrlRichEdit_SetTabStops

Устанавливает позиции табуляции

#include <GuiRichEdit.au3>
_GUICtrlRichEdit_SetTabStops($hWnd, $vTabStops [, $fRedraw = True])

Параметры

$hWnd Дескриптор элемента
$VTabStops Позиция(и) табуляции в единицах пространства:
    Если строка, то позиции табуляции указываются через разделитель точка с запятой.
    Если число, то позиции табуляции каждые единиц пространства
$fRedraw [необязательный] Следует ли перерисовать элемент - True (по умолчанию) или False

Возвращаемое значение

Успех:Возвращает True
Ошибка:Возвращает False и устанавливает @error
@error:101 - $HWnd не является дескриптором
1021 - $vTabStops не является строкой или числом
1022 - $vTabStops является строкой, но позиции табуляции в нём не является положительным числом
1023 - $vTabStops является пустой строкой
1024 - $vTabStops является числом, но нулём или отрицательным
103 - $fRedraw не является True или False

Примечания

Space units are initially inches.
Чтобы напечатать табуляцию в элементе, нажмите Ctrl+Tab

См. также

_GUICtrlRichEdit_SetParaTabStops, _GUICtrlRichEdit_SetSpaceUnit

См. также

Искать EM_SETTABSTOPS в библиотеке MSDN

Пример

#include <GuiRichEdit.au3>
#include <GUIConstantsEx.au3>
#include <WindowsConstants.au3>

Global $lblMsg, $hRichEdit

Main()

Func Main()
    Local $hGui, $btnNext, $iStep = 0
    $hGui = GUICreate(StringTrimRight(@ScriptName, 4), 420, 350, -1, -1)
    $hRichEdit = _GUICtrlRichEdit_Create($hGui, 'Это тест.', 10, 10, 400, 220, _
            BitOR($ES_MULTILINE, $WS_VSCROLL, $ES_AUTOVSCROLL))
    $lblMsg = GUICtrlCreateLabel("", 10, 235, 300, 60)
    $btnNext = GUICtrlCreateButton("Далее", 270, 310, 60, 30)
    GUISetState()

    _GUICtrlRichEdit_SetText($hRichEdit, "Текст 1" & @TAB & "Текст 2" & @TAB & "Текст 3")
    While 1
        Switch GUIGetMsg()
            Case $GUI_EVENT_CLOSE
                _GUICtrlRichEdit_Destroy($hRichEdit)
                GUIDelete()
                Exit
            Case $btnNext
                $iStep += 1
                Switch $iStep
                    Case 1
                        _GUICtrlRichEdit_SetTabStops($hRichEdit, 1)
                        GUICtrlSetData($lblMsg, "1. Устанавливает позиции табуляции на каждый дюйм")
                    Case 2
                        _GUICtrlRichEdit_SetTabStops($hRichEdit, "0.5;1.5")
                        GUICtrlSetData($lblMsg, "2. Устанавливает позиции табуляции на 0.5 и 1.5 дюйма")

                        _GUICtrlRichEdit_Deselect($hRichEdit)
                        ; Весь RTF-код сохраняет в файл на Рабочем столе чтобы посмотреть в Word
                        ; _GUICtrlRichEdit_StreamToFile($hRichEdit, @DesktopDir & "\gcre.rtf")
                        GUICtrlSetState($btnNext, $GUI_DISABLE)
                EndSwitch
        EndSwitch
    WEnd
EndFunc