Функция _GUICtrlRichEdit_SetSel

 ↑  ←  Описание функции

_GUICtrlRichEdit_SetSel

Устанавливает выделение текста в указанных позициях начала и конца

#include <GuiRichEdit.au3>
_GUICtrlRichEdit_SetSel($hWnd, $iAnchor, $iActive [, $fHideSel = False])

Параметры

$hWnd Дескриптор элемента
$iAnchor Позиция первого символа выделения
    Специальное значение: -1 - конец текста
$iActive Позиция последнего символа выделения
    Специальное значение: -1 - конец текста
$fHideSel [необязательный] True - скрыть выделение

Возвращаемое значение

Успех:Возвращает True
Ошибка:Возвращает False и устанавливает @error
@error:101 - $HWnd не является дескриптором
102 - $iAnchor не является положительным числом или 0 или -1
103 - $iActive не является положительным числом или 0 или -1
104 - $fHideSel не является True или False

Примечания

Первый символ текста в элементе имеет позицию 0

$iActive может быть меньше, чем $iAnchor

См. также

_GUICtrlRichEdit_GetSel, _GUICtrlRichEdit_GetSelAA, _GUICtrlRichEdit_Deselect, _GUICtrlRichEdit_IsTextSelected, _GUICtrlRichEdit_GotoCharPos

См. также

Искать EM_EXSETSEL в библиотеке MSDN

Пример

#include <GuiRichEdit.au3>
#include <GUIConstantsEx.au3>
#include <WindowsConstants.au3>

Global $lblMsg, $hRichEdit

Main()

Func Main()
    Local $hGui, $btnNext, $iStep = 0, $iPos
    $hGui = GUICreate(StringTrimRight(@ScriptName, 4), 420, 350, -1, -1)
    $hRichEdit = _GUICtrlRichEdit_Create($hGui, 'Это тест.', 10, 10, 400, 220, _
            BitOR($ES_MULTILINE, $WS_VSCROLL, $ES_AUTOVSCROLL, $ES_NOHIDESEL))
    _GUICtrlRichEdit_AutoDetectURL($hRichEdit, True)
    _GUICtrlRichEdit_AppendText($hRichEdit, @CR & "http://www.autoitscript.com")
    $lblMsg = GUICtrlCreateLabel("", 10, 235, 300, 60)
    $btnNext = GUICtrlCreateButton("Далее", 270, 310, 60, 30)
    GUISetState()

    While 1
        Switch GUIGetMsg()
            Case $GUI_EVENT_CLOSE
                _GUICtrlRichEdit_Destroy($hRichEdit)
                GUIDelete()
                Exit
            Case $btnNext
                $iStep += 1
                Switch $iStep
                    Case 1
                        _GUICtrlRichEdit_SetSel($hRichEdit, 2, 5)
                        Report("1. Текст выделен в позициях:")
                    Case 2
                        $iPos = _GUICtrlRichEdit_GetFirstCharPosOnLine($hRichEdit, 2)
                        _GUICtrlRichEdit_SetSel($hRichEdit, $iPos, $iPos + 3)
                        Report("2. Текст выделен в позициях:")
                        GUICtrlSetState($btnNext, $GUI_DISABLE)
                EndSwitch
        EndSwitch
    WEnd
EndFunc   ;==>Main

Func Report($sMsg)
    Local $aPos  = _GUICtrlRichEdit_GetSel($hRichEdit)
    $sMsg &=   ' ' & $aPos[0] & ', '  & $aPos[1]
    GUICtrlSetData($lblMsg, $sMsg)
    ControlFocus($hRichEdit, "", "")
EndFunc   ;==>Report