_GUICtrlRichEdit_GetSelAA
Возвращает якорь и активный межсимвольные позиции выделенного текста, именно в таком порядке
#include <GuiRichEdit.au3>
_GUICtrlRichEdit_GetSelAA($hWnd)
Параметры
| $hWnd | Дескриптор элемента |
Возвращаемое значение
| Успех: | Возвращает массив следующего формата [<якорь>, <активный>] |
| Ошибка: | устанавливает @error |
| @error: | -1 - текст не выделен |
| 101 - $HWnd не является дескриптором |
Примечания
Первый символ текста после межсимвольной позиции - 0.См. также
_GUICtrlRichEdit_SetSel, _GUICtrlRichEdit_GetSel, _GUICtrlRichEdit_GetScrollPosСм. также
Искать EM_EXGETSEL в библиотеке MSDNПример
#include <GuiRichEdit.au3>
#include <GUIConstantsEx.au3>
#include <WindowsConstants.au3>
Global $lblMsg, $hRichEdit
Main()
Func Main()
Local $hGui, $btnNext, $iStep = 0
$hGui = GUICreate(StringTrimRight(@ScriptName, 4), 420, 350, -1, -1)
$hRichEdit = _GUICtrlRichEdit_Create($hGui, "Это тест.", 10, 10, 400, 220, _
BitOR($ES_MULTILINE, $WS_VSCROLL, $ES_AUTOVSCROLL))
$lblMsg = GUICtrlCreateLabel("", 10, 235, 300, 60)
$btnNext = GUICtrlCreateButton("Далее", 270, 310, 60, 30)
GUISetState()
_GUICtrlRichEdit_SetSel($hRichEdit, 7, 2)
While 1
Switch GUIGetMsg()
Case $GUI_EVENT_CLOSE
_GUICtrlRichEdit_Destroy($hRichEdit)
GUIDelete()
Exit
Case $btnNext
$iStep += 1
Switch $iStep
Case 1
Report("1. Выделено от большего к меньшему")
Case 2
_GUICtrlRichEdit_SetSel($hRichEdit, 2, 7)
Report("2. Выделено от меньшего к большему")
GUICtrlSetState($btnNext, $GUI_DISABLE)
EndSwitch
EndSwitch
WEnd
EndFunc ;==>Main
Func Report($sMsg)
Local $aRet = _GUICtrlRichEdit_GetSelAA($hRichEdit)
$sMsg &= @CR & @CR & "Позиции: " & $aRet[0] & ", " & $aRet[1]
GUICtrlSetData($lblMsg, $sMsg)
ControlFocus($hRichEdit, "", "")
EndFunc ;==>Report