Функция _GUICtrlRichEdit_GetScrollPos

 ↑  ←  Описание функции

_GUICtrlRichEdit_GetScrollPos

Возвращает позицию прокрутки в элементе

#include <GuiRichEdit.au3>
_GUICtrlRichEdit_GetScrollPos($hWnd)

Параметры

$hWnd Дескриптор элемента

Возвращаемое значение

Успех:Возвращает массив, содержащий [x, y]
Ошибка:устанавливает @error
@error:101 - $HWnd не является дескриптором

Примечания

Позиция прокрутки является левый верхний угол элемента

См. также

_GUICtrlRichEdit_SetScrollPos, _GUICtrlRichEdit_GetSelAA

См. также

Искать EM_GETSCROLLPOS в библиотеке MSDN

Пример

#include <GuiRichEdit.au3>
#include <GUIConstantsEx.au3>
#include <WindowsConstants.au3>

Global $lblMsg, $hRichEdit

Main()

Func Main()
    Local $hGui, $btnNext, $iStep = 0
    $hGui = GUICreate(StringTrimRight(@ScriptName, 4), 420, 350, -1, -1)
    $hRichEdit = _GUICtrlRichEdit_Create($hGui, "", 10, 10, 400, 220, _
            BitOR($ES_MULTILINE, $WS_VSCROLL, $ES_AUTOVSCROLL))
    $lblMsg = GUICtrlCreateLabel("", 10, 235, 300, 60)
    $btnNext = GUICtrlCreateButton("Далее", 270, 310, 60, 30)
    GUISetState()

    _GUICtrlRichEdit_SetText($hRichEdit, "Строка 1")
    For $i = 2 To 20
        _GUICtrlRichEdit_AppendText($hRichEdit, @CRLF & "Строка " & $i)
    Next
    Report("0. Начальная позиция прокрутки, показывающая позицию вставки")

    While 1
        Switch GUIGetMsg()
            Case $GUI_EVENT_CLOSE
                _GUICtrlRichEdit_Destroy($hRichEdit)
                GUIDelete()
                Exit
            Case $btnNext
                $iStep += 1
                Switch $iStep
                    Case 1
                        _GUICtrlRichEdit_SetScrollPos($hRichEdit, 0, 0)
                        Report("1. Прокручивает к верху")
                    Case 2
                        _GUICtrlRichEdit_SetScrollPos($hRichEdit, 7, 22)
                        Report("2. Прокручивает немного вниз и вправо")
                        GUICtrlSetState($btnNext, $GUI_DISABLE)
                EndSwitch
        EndSwitch
    WEnd
EndFunc   ;==>Main

Func Report($sMsg)
    Local $aPos = _GUICtrlRichEdit_GetScrollPos($hRichEdit)
    $sMsg &=  @CR & @CR & "Позиция прокрутки " & $aPos[0] & "; " & $aPos[1]
    GUICtrlSetData($lblMsg, $sMsg)
    ControlFocus($hRichEdit, "", "")
EndFunc   ;==>Report