_GUICtrlRichEdit_ReplaceText
Заменяет выделенный текст
#include <GuiRichEdit.au3>
_GUICtrlRichEdit_ReplaceText($hWnd, $sText [, $fCanUndo = True])
Параметры
| $hWnd | Дескриптор элемента |
| $sText |
Текст замены |
| $fCanUndo | [необязательный] Возможность отмены операции. True (по умолчанию) или False |
Возвращаемое значение
| Успех: | Возвращает True |
| Ошибка: | Возвращает False и устанавливает @error |
| @error: | 101 - $HWnd не является дескриптором |
| 103 - $fCanUndo не является True или False | |
| -1 - нет выделенного текста |
См. также
_GUICtrlRichEdit_InsertText, _GUICtrlRichEdit_AppendText, _GUICtrlRichEdit_SetTextСм. также
Искать EM_REPLACESEL в библиотеке MSDNПример
#include <GuiRichEdit.au3>
#include <GUIConstantsEx.au3>
#include <WindowsConstants.au3>
Main()
Func Main()
Local $hGui, $btnNext, $iStep = 0, $lblMsg, $hRichEdit
$hGui = GUICreate(StringTrimRight(@ScriptName, 4), 420, 350, -1, -1)
$hRichEdit = _GUICtrlRichEdit_Create($hGui, 'Это тест.', 10, 10, 400, 220, _
BitOR($ES_MULTILINE, $WS_VSCROLL, $ES_AUTOVSCROLL))
$lblMsg = GUICtrlCreateLabel("", 10, 235, 300, 60)
$btnNext = GUICtrlCreateButton("Далее", 270, 310, 60, 30)
GUISetState()
While 1
Switch GUIGetMsg()
Case $GUI_EVENT_CLOSE
_GUICtrlRichEdit_Destroy($hRichEdit)
GUIDelete()
Exit
Case $btnNext
$iStep += 1
Switch $iStep
Case 1
_GUICtrlRichEdit_SetSel($hRichEdit, 0, 5)
Case 2
_GUICtrlRichEdit_ReplaceText($hRichEdit, "/замена выделенного текста/")
GUICtrlSetData($lblMsg, "Текст был заменён")
Case 3
_GUICtrlRichEdit_SetSel($hRichEdit, 0, 27)
_GUICtrlRichEdit_ReplaceText($hRichEdit, "")
GUICtrlSetData($lblMsg, "Текст удалён заменой на пустую строку")
GUICtrlSetState($btnNext, $GUI_DISABLE)
EndSwitch
EndSwitch
WEnd
EndFunc ;==>Main