Функция _GUICtrlRichEdit_InsertText

 ↑  ←  Описание функции

_GUICtrlRichEdit_InsertText

Вставить текст в позицию курсора

#include <GuiRichEdit.au3>
_GUICtrlRichEdit_InsertText($hWnd, $sText)

Параметры

$hWnd Дескриптор элемента
$sText Вставляемый текст

Возвращаемое значение

Succcess:Возвращает True
Ошибка:Возвращает False и устанавливает @error
@error:101 - $HWnd не является дескриптором
102 - $sText = "" (пустая строка)
103 - Не удалось вставить текст

См. также

_GUICtrlRichEdit_AppendText, _GUICtrlRichEdit_ReplaceText, _GUICtrlRichEdit_SetText, _GUICtrlRichEdit_GetText

См. также

Искать EM_SETTEXTEX в библиотеке MSDN

Пример

#include <GuiRichEdit.au3>
#include <GUIConstantsEx.au3>
#include <WindowsConstants.au3>
OnAutoItExitRegister('_OnExit') ; Освобождает ресурсы RichEdit даже при завершении скрипта с ошибкой

; Создание GUI
$hGui = GUICreate("Вставляет текст", 420, 350, -1, -1)
$hRichEdit = _GUICtrlRichEdit_Create($hGui, "Это текст", 10, 10, 400, 220, _
        BitOR($ES_MULTILINE, $WS_VSCROLL, $ES_AUTOVSCROLL))
$lblMsg = GUICtrlCreateLabel("Строка состояния", 10, 235, 300, 60)
$iButton = GUICtrlCreateButton("Вставить текст", 200, 310, 110, 30)
GUISetState()

While 1
    Switch GUIGetMsg()
        Case $iButton
            ; Вставляет текст в позицию текстового курсора
            $sMsg = _GUICtrlRichEdit_InsertText($hRichEdit, '/вставленный текст/')
            GUICtrlSetData($lblMsg, $sMsg)
        Case $GUI_EVENT_CLOSE
            Exit
    EndSwitch
WEnd

Func _OnExit()
    ; Для версий ниже 3.3.8.0 обязательно удаление RichEdit или GUI для освобождения ресурсов RichEdit
    _GUICtrlRichEdit_Destroy($hRichEdit)
    GUIDelete()
EndFunc