Функция _GUICtrlListView_GetColumn

         Описание функции

_GUICtrlListView_GetColumn

Возвращает атрибуты колонки

#include <GuiListView.au3>
_GUICtrlListView_GetColumn($hWnd, $iIndex)

Параметры

$hWnd Дескриптор или идентификатор элемента
$iIndex Индекс колонки, отсчёт от 0

Возвращаемое значение

Возвращает массив следующего формата:
        [0] - Выравнивание заголовка колонки и текста подпункта колонки:
        0 - Выравнивание текста по левому краю
        1 - Выравнивание текста по правому краю
        2 - Выравнивание текста по центру
        [1] - True, если пункт отображает изображение из списка изображений
        [2] - True, если bitmap находится справа от текста
        [3] - True, если заголовок содержит изображение
        [4] - Ширина колонки в пикселях
        [5] - Текст заголовка колонки
        [6] - Индекс подпункта соответствующий колонке
        [7] - Индекс изображения в пределах списка изображений
        [8] - Порядковый номер колонки

См. также

_GUICtrlListView_SetColumn, _GUICtrlListView_JustifyColumn

Пример

#include <GUIConstantsEx.au3>
#include <GuiListView.au3>

$Debug_LV = False ; Проверяет ClassName передаваемый в ListView функции. Установите True и используйте дескриптор от другого элемента, чтобы увидеть как это работает

_Main()

Func _Main()
    Local $aInfo, $hListView

    GUICreate("ListView - Получает атрибуты колонки", 400, 300)
    $hListView = GUICtrlCreateListView("Колонка1|Колонка2|Колонка3", 2, 2, 394, 268)
    _GUICtrlListView_SetExtendedListViewStyle($hListView, BitOR($LVS_EX_FULLROWSELECT, $LVS_EX_CHECKBOXES))
    _GUICtrlListView_SetColumnWidth($hListView, 0, 100)
    GUISetState()

    GUICtrlCreateListViewItem("Индекс 0|Данные 1|Дополнительно 1", $hListView)
    GUICtrlCreateListViewItem("Индекс 1|Данные 2|Дополнительно 2", $hListView)
    GUICtrlCreateListViewItem("Индекс 2|Данные 3|Дополнительно 3", $hListView)
    GUICtrlCreateListViewItem("Индекс 3|Данные 4|Дополнительно 4", $hListView)
    GUICtrlCreateListViewItem("Индекс 4|Данные 5|Дополнительно 5", $hListView)

    ; Изменяет колонку
    $aInfo = _GUICtrlListView_GetColumn($hListView, 0)
    MsgBox(4160, "Информация", "Ширина первой колонки: " & $aInfo[4])
    _GUICtrlListView_SetColumn($hListView, 0, "Новая колонка 1", 150)
    $aInfo = _GUICtrlListView_GetColumn($hListView, 0)
    MsgBox(4160, "Информация", "Ширина первой колонки: " & $aInfo[4])

    ; Цикл выполняется, пока окно не будет закрыто
    Do
    Until GUIGetMsg() = $GUI_EVENT_CLOSE

    GUIDelete()
EndFunc   ;==>_Main