Функция _GUICtrlListView_JustifyColumn

         Описание функции

_GUICtrlListView_JustifyColumn

Установить выравнивание текста в указанной колонке ListView

#include <GuiListView.au3>
_GUICtrlListView_JustifyColumn($hWnd, $iIndex [, $iAlign = -1])

Параметры

$hWnd Дескриптор или идентификатор элемента
$iIndex Индекс колонки, отсчёт от 0
$iAlign [необязательный] Выравнивание заголовка колонки и текста подпунктов в колонке:
    0 - Текст выравнивается по левому краю
    1 - Текст выравнивается по правому краю
    2 - Текст выравнивается по центру

Возвращаемое значение

Успех:Возвращает True
Ошибка:Возвращает False

См. также

_GUICtrlListView_GetColumn, _GUICtrlListView_SetColumn

Пример

#include <File.au3>
#include <GuiListView.au3>
#include <GUIConstantsEx.au3>

; Получает список файлов
$aFiles = _FileListToArray(@WindowsDir, "*.*", 1)

; Создание GUI
GUICreate("Выравнивание текста в колонке")
$iListView = GUICtrlCreateListView("Размер|Файл", 5, 5, 385, 390, -1, $LVS_EX_FULLROWSELECT)
_GUICtrlListView_SetColumnWidth($iListView, 0, 70)
_GUICtrlListView_SetColumnWidth($iListView, 1, 280)

; Выравнивание текста по правому краю в колонке 0
_GUICtrlListView_JustifyColumn($iListView, 0, 1)

; Добавляет пункты
For $i = 1 To $aFiles[0]
    GUICtrlCreateListViewItem(FileGetSize(@WindowsDir & '\' & $aFiles[$i]) & "|" & $aFiles[$i], $iListView)
Next
GUISetState()

Do
Until GUIGetMsg() = $GUI_EVENT_CLOSE