Функция _GUICtrlListView_SetColumnWidth

         Описание функции

_GUICtrlListView_SetColumnWidth

Изменяет ширину колонки

#include <GuiListView.au3>
_GUICtrlListView_SetColumnWidth($hWnd, $iCol, $iWidth)

Параметры

$hWnd Дескриптор или идентификатор элемента
$iCol Индекс существующей колонки, отсчёт от 0. В режиме списка этот параметр должен быть равен 0
$iWidth Новая ширина колонки в пикселях.
    Для режима report-view, поддерживаются следующие специальные значения:
    $LVSCW_AUTOSIZE - Автоматически установить размер колонок.
    $LVSCW_AUTOSIZE_USEHEADER - Автоматически установить размер колонок по размеру текста в заголовке.
    Если вы используете этот параметр для последней колонки, то она автоматически занимает оставшееся пространство ListView

Возвращаемое значение

Успех:Возвращает True
Ошибка:Возвращает False

См. также

_GUICtrlListView_GetColumnWidth, _GUICtrlListView_HideColumn

Пример

#include <GUIConstantsEx.au3>
#include <GuiListView.au3>

$Debug_LV = False ; Проверяет ClassName передаваемый в ListView функции. Установите True и используйте дескриптор от другого элемента, чтобы увидеть как это работает

_Main()

Func _Main()
    Local $hListView

    GUICreate("ListView Устанавливает ширину колонки", 400, 300)
    $hListView = GUICtrlCreateListView("Колонка 1|Колонка 2|Колонка 3|Колонка 4", 2, 2, 394, 268)
    GUISetState()

    ; Изменяет ширину первой колонки
    MsgBox(4160, "Информация", "Ширина первой колонки: " & _GUICtrlListView_GetColumnWidth($hListView, 0))
    _GUICtrlListView_SetColumnWidth($hListView, 0, 150)
    MsgBox(4160, "Информация", "Ширина первой колонки: " & _GUICtrlListView_GetColumnWidth($hListView, 0))

    ; Цикл выполняется, пока окно не будет закрыто
    Do
    Until GUIGetMsg() = $GUI_EVENT_CLOSE

    GUIDelete()
EndFunc   ;==>_Main