Функция _GUICtrlListView_SetExtendedListViewStyle

         Описание функции

_GUICtrlListView_SetExtendedListViewStyle

Устанавливает расширенные стили

#include <GuiListView.au3>
_GUICtrlListView_SetExtendedListViewStyle($hWnd, $iExStyle [, $iExMask = 0])

Параметры

$hWnd Дескриптор или идентификатор элемента
$iExStyle Расширенные стили элемента ListView:
    $LVS_EX_BORDERSELECT - Если этот стиль установлен, то у выбранного элемента изменяется цвет рамки, а не происходит выделение пункта
    $LVS_EX_CHECKBOXES - Добавляет check-boxes для пунктов в элементе ListView
    $LVS_EX_DOUBLEBUFFER - Перерисовка с помощью двойной буферизации, которая уменьшает мерцание
    $LVS_EX_FLATSB - Плоская полоса прокрутки в элементе ListView
    $LVS_EX_FULLROWSELECT - При клике пункта или подпункта, выделяется сам пункт и все его подпункты
    $LVS_EX_GRIDLINES - Отображает сетку вокруг пунктов и подпунктов
    $LVS_EX_HEADERDRAGDROP - Разрешает перетаскивание колонок за заголовок (drag-and-drop) изменяя их порядок
    $LVS_EX_INFOTIP - Высылается уведомительное сообщение $LVN_GETINFOTIP перед отображением всплывающей подсказки (ToolTip)
    $LVS_EX_LABELTIP - If not set, the unfolds partly hidden labels only for the large icon mode
    $LVS_EX_MULTIWORKAREAS - The control will not autoarrange its icons until one or more work areas are defined
    $LVS_EX_ONECLICKACTIVATE - Элемент высылает сообщение $LVN_ITEMACTIVATE , когда пользователь кликает на пункте
    $LVS_EX_REGIONAL - Sets the control region to include only the item icons and text
    $LVS_EX_SIMPLESELECT - In icon view moves the state image of the control to the top right
    $LVS_EX_SUBITEMIMAGES - Позволяет отображать изображения в подпунктах.
    $LVS_EX_TRACKSELECT - Горячий выбор в элементе ListView. Это означает автоматическое выделение пункта при наведении на него курсора мыши и удержание в течение определенного периода времени
    $LVS_EX_TWOCLICKACTIVATE - Элемент высылает сообщение $LVN_ITEMACTIVATE, когда пользователь выполняет двойной клик на пункте
    $LVS_EX_UNDERLINECOLD - Causes non-hot items that may be activated to be displayed with underlined text
    $LVS_EX_UNDERLINEHOT - Causes hot items that may be activated to be displayed with underlined text
$iExMask [необязательный] Specifies which styles in $iExStyle are to be affected. This parameter can be a combination of
    extended styles. Only the extended styles in $iExMask will be changed. All other styles will be maintained as
    they are. If this parameter is zero, all of the styles in $iExStyle will be affected.

Возвращаемое значение

Возвращает комбинацию предыдущих расширенных стилей

См. также

_GUICtrlListView_GetExtendedListViewStyle

Пример

#include <GUIConstantsEx.au3>
#include <GuiListView.au3>
#include <GuiImageList.au3>

$Debug_LV = False ; Проверяет ClassName передаваемый в ListView функции. Установите True и используйте дескриптор от другого элемента, чтобы увидеть как это работает

_Main()

Func _Main()
    Local $hImage, $hListView

    ; Создаёт GUI
    GUICreate("Устанавливает расширенный стиль", 400, 300)
    $hListView = GUICtrlCreateListView("", 2, 2, 394, 268)

    ; Устанавливает расширенный стиль
    _GUICtrlListView_SetExtendedListViewStyle($hListView, BitOR($LVS_EX_FULLROWSELECT, $LVS_EX_SUBITEMIMAGES))
    GUISetState()

    ; Загружает изображения
    $hImage = _GUIImageList_Create()
    _GUIImageList_Add($hImage, _GUICtrlListView_CreateSolidBitMap($hListView, 0xFF0000, 16, 16))
    _GUIImageList_Add($hImage, _GUICtrlListView_CreateSolidBitMap($hListView, 0x00FF00, 16, 16))
    _GUIImageList_Add($hImage, _GUICtrlListView_CreateSolidBitMap($hListView, 0x0000FF, 16, 16))
    _GUICtrlListView_SetImageList($hListView, $hImage, 1)

    ; Добавляет колонки
    _GUICtrlListView_InsertColumn($hListView, 0, "Колонка 1", 120)
    _GUICtrlListView_InsertColumn($hListView, 1, "Колонка 2", 120)
    _GUICtrlListView_InsertColumn($hListView, 2, "Колонка 3", 120)

    ; Добавляет пункты
    _GUICtrlListView_AddItem($hListView, "Стр 1: Кол 1", 0)
    _GUICtrlListView_AddSubItem($hListView, 0, "Стр 1: Кол 2", 1, 1)
    _GUICtrlListView_AddSubItem($hListView, 0, "Стр 1: Кол 3", 2, 2)
    _GUICtrlListView_AddItem($hListView, "Стр 2: Кол 1", 1)
    _GUICtrlListView_AddSubItem($hListView, 1, "Стр 2: Кол 2", 1, 2)
    _GUICtrlListView_AddItem($hListView, "Стр 3: Кол 1", 2)

    ; Цикл выполняется, пока окно не будет закрыто
    Do
    Until GUIGetMsg() = $GUI_EVENT_CLOSE
    GUIDelete()
EndFunc   ;==>_Main