Функция _GUIImageList_Create

 ↑  ←  Описание функции

_GUIImageList_Create

Создаёт элемент ImageList

#include <GuiImageList.au3>
_GUIImageList_Create([$iCX=16 [, $iCY=16 [, $iColor=4 [, $iOptions=0 [, $iInitial=4 [, $iGrow=4]]]]]])

Параметры

$iCX [необязательный] Ширина каждого изображения в пикселях
$iCY [необязательный] Высота каждого изображения в пикселях
$iColor [необязательный] Глубина цвета изображения:
    0 - По умолчанию
    1 - 4 битная DIB-секция
    2 - 8 битная DIB-секция
    3 - 16 битная DIB-секция
    4 - 24 битная DIB-секция
    5 - 32 битная DIB-секция
    6 - устройство-зависимый bitmap
$iOptions [необязательный] Опциональный флаг. Может быть комбинацией следующих значений:
    1 - Использовать маску
    2 - The images in the lists are mirrored
    4 - Список изображений состоит из полоски содержащей несколько изображений
$iInitial [необязательный] Количество изображений, которое изначально содержит список изображений
$iGrow [необязательный] Количество изображений, используя которые список изображений может увеличится, когда система нуждается в том, чтобы освободить место для новых изображений. Этот параметр представляет количество новых изображений, которых список изображений может вместить.

Возвращаемое значение

Успех:Возвращает дескриптор нового элемента
Ошибка:Возвращает 0

Примечания

DIB (Device Independent Bitmaps) - устройство-независимые изображения
DDB (Device Dependent Bitmaps) - устройство-зависимые изображения

См. также

_GUIImageList_Destroy

Пример

#include <GUIConstantsEx.au3>
#include <WinAPI.au3>
#include <GuiListView.au3>
#include <GuiImageList.au3>
#include <WindowsConstants.au3>

_Main()

Func _Main()
    Local $listview, $hImage
    Local $exStyles = BitOR($LVS_EX_GRIDLINES, $LVS_EX_FULLROWSELECT, $LVS_EX_SUBITEMIMAGES)

    GUICreate("ImageList Create", 400, 300)
    $listview = GUICtrlCreateListView("", 2, 2, 394, 268, BitOR($LVS_SHOWSELALWAYS, $LVS_NOSORTHEADER, $LVS_REPORT))
    _GUICtrlListView_SetExtendedListViewStyle($listview, $exStyles)
    GUISetState()

    ; Загружает изображения
    $hImage = _GUIImageList_Create(11, 11)
    _GUIImageList_Add($hImage, _WinAPI_CreateSolidBitmap(GUICtrlGetHandle($listview), 0xFF0000, 11, 11))
    _GUIImageList_Add($hImage, _WinAPI_CreateSolidBitmap(GUICtrlGetHandle($listview), 0x00FF00, 11, 11))
    _GUIImageList_Add($hImage, _WinAPI_CreateSolidBitmap(GUICtrlGetHandle($listview), 0x0000FF, 11, 11))
    _GUICtrlListView_SetImageList($listview, $hImage, 1)

    ; Добавляет колонки
    _GUICtrlListView_AddColumn($listview, "Пункты", 120)

    ; Добавляет пункты
    _GUICtrlListView_AddItem($listview, "Пункт 1", 0)
    _GUICtrlListView_AddItem($listview, "Пункт 2", 1)
    _GUICtrlListView_AddItem($listview, "Пункт 3", 2)

    ; Цикл выполняется, пока окно не будет закрыто
    Do
    Until GUIGetMsg() = $GUI_EVENT_CLOSE
    GUIDelete()
EndFunc   ;==>_Main