Функция _GUICtrlComboBoxEx_SetMinVisible

         Описание функции

_GUICtrlComboBoxEx_SetMinVisible

Устанавливает минимальное количество видимых строк в раскрывающемся списке ComboBox

#include <GuiComboBoxEx.au3>
_GUICtrlComboBoxEx_SetMinVisible($hWnd, $iMinimum)

Параметры

$hWnd Дескриптор элемента
$iMinimum Число, указывающее минимальное количество видимых строк

Возвращаемое значение

Успех:Возвращает True
Ошибка:Возвращает False

Примечания

Если количество строк в раскрывающемся списке больше, чем минимум, то в ComboBox появляется полоса прокрутки. По умолчанию минимальное количество видимых строк равно 30.

Эта функция игнорируется, если ComboBox имеет стиль $CBS_NOINTEGRALHEIGHT

См. также

_GUICtrlComboBoxEx_GetMinVisible

Пример

#include <GuiComboBoxEx.au3>
#include <GuiImageList.au3>
#include <GUIConstantsEx.au3>

$Debug_CB = False ; Проверяет ClassName передаваемый в ComboBox/ComboBoxEx функции. Установите True и используйте дескриптор от другого элемента, чтобы увидеть как это работает

_Main()

Func _Main()
    Local $hGUI, $hImage, $iImage, $hCombo

    ; Создаёт GUI
    $hGUI = GUICreate("Устанавливает минимально видимых", 400, 300)
    $hCombo = _GUICtrlComboBoxEx_Create ($hGUI, "", 2, 2, 394, 100)
    GUISetState()

    $hImage = _GUIImageList_Create (16, 16, 5, 3)
    _GUIImageList_AddIcon ($hImage, @SystemDir & "\shell32.dll", 110)
    _GUIImageList_AddIcon ($hImage, @SystemDir & "\shell32.dll", 131)
    _GUIImageList_AddIcon ($hImage, @SystemDir & "\shell32.dll", 165)
    _GUIImageList_AddIcon ($hImage, @SystemDir & "\shell32.dll", 168)
    _GUIImageList_AddIcon ($hImage, @SystemDir & "\shell32.dll", 137)
    _GUIImageList_AddIcon ($hImage, @SystemDir & "\shell32.dll", 146)
    _GUIImageList_Add ($hImage, _GUICtrlComboBoxEx_CreateSolidBitMap ($hCombo, 0xFF0000, 16, 16))
    _GUIImageList_Add ($hImage, _GUICtrlComboBoxEx_CreateSolidBitMap ($hCombo, 0x00FF00, 16, 16))
    _GUIImageList_Add ($hImage, _GUICtrlComboBoxEx_CreateSolidBitMap ($hCombo, 0x0000FF, 16, 16))
    _GUICtrlComboBoxEx_SetImageList ($hCombo, $hImage)

    _GUICtrlComboBoxEx_InitStorage ($hCombo, 150, 300)
    _GUICtrlComboBoxEx_BeginUpdate ($hCombo)

    For $x = 0 To 149
        $iImage = Random(0, 8, 1)
        _GUICtrlComboBoxEx_AddString ($hCombo, StringFormat("%03d : Рандомная строка", Random(1, 100, 1)), $iImage, $iImage)
    Next
    _GUICtrlComboBoxEx_EndUpdate ($hCombo)

    MsgBox(4160, "Информация", "Минимально видимых: " & _GUICtrlComboBoxEx_GetMinVisible ($hCombo))
    MsgBox(4160, "Информация", "Успех установки минимально видимых: " & _GUICtrlComboBoxEx_SetMinVisible ($hCombo, 50))
    MsgBox(4160, "Информация", "Минимально видимых: " & _GUICtrlComboBoxEx_GetMinVisible ($hCombo))

    Do
    Until GUIGetMsg() = $GUI_EVENT_CLOSE
EndFunc   ;==>_Main