Функция _GUICtrlComboBoxEx_AddString

         Описание функции

_GUICtrlComboBoxEx_AddString

Добавляет строку

#include <GuiComboBoxEx.au3>
_GUICtrlComboBoxEx_AddString($hWnd, $sText [, $iImage = -1 [, $iSelecteImage = -1 [, $iOverlayImage = -1 [, $iIndent = -1 [, $iParam = -1]]]]])

Параметры

$hWnd Дескриптор элемента
$sText Текст пункта. Если установлено -1, то пункт устанавливается через код события $CBEN_GETDISPINFO.
$iImage [необязательный] Индекс иконки в списке изображений, отсчёт от 0.
$iSelecteImage [необязательный] Индекс иконки в списке изображений, отсчёт от 0.
$iOverlayImage [необязательный] Индекс иконки в списке изображений, отсчёт от 0.
$iIndent [необязательный] Количество отступов для пункта. Один отступ равен ширине изображения.
$iParam [необязательный] Значение связанное с пунктом

Возвращаемое значение

Успех:Возвращает индекс нового пункта
Ошибка:Возвращает -1

См. также

_GUICtrlComboBoxEx_DeleteString, _GUICtrlComboBoxEx_InitStorage

Пример

#include <GuiComboBoxEx.au3>
#include <GuiImageList.au3>
#include <GUIConstantsEx.au3>

$Debug_CB = False ; Проверяет ClassName передаваемый в ComboBox/ComboBoxEx функции. Установите True и используйте дескриптор от другого элемента, чтобы увидеть как это работает

_Main()

Func _Main()
    Local $hGUI, $hImage, $hCombo


    ; Создаёт GUI
    $hGUI = GUICreate("Добавляет строки", 400, 300)
    $hCombo = _GUICtrlComboBoxEx_Create ($hGUI, "", 2, 2, 394, 100)
    GUISetState()

    $hImage = _GUIImageList_Create (16, 16, 5, 3)
    For $x = 0 To 146
        _GUIImageList_AddIcon ($hImage, @SystemDir & "\shell32.dll", $x)
    Next
    _GUIImageList_Add ($hImage, _GUICtrlComboBoxEx_CreateSolidBitMap ($hCombo, 0xFF0000, 16, 16))
    _GUIImageList_Add ($hImage, _GUICtrlComboBoxEx_CreateSolidBitMap ($hCombo, 0x00FF00, 16, 16))
    _GUIImageList_Add ($hImage, _GUICtrlComboBoxEx_CreateSolidBitMap ($hCombo, 0x0000FF, 16, 16))
    _GUICtrlComboBoxEx_SetImageList ($hCombo, $hImage)

    _GUICtrlComboBoxEx_InitStorage ($hCombo, 150, 300)

    _GUICtrlComboBoxEx_BeginUpdate ($hCombo)
    For $x = 0 To 149
        _GUICtrlComboBoxEx_AddString ($hCombo, StringFormat("%03d : Рандомная строка", Random(1, 200, 1)), $x, $x)
    Next
    _GUICtrlComboBoxEx_EndUpdate ($hCombo)

    Do
    Until GUIGetMsg() = $GUI_EVENT_CLOSE
EndFunc   ;==>_Main