Функция _GUICtrlComboBoxEx_InitStorage

         Описание функции

_GUICtrlComboBoxEx_InitStorage

Выделяет память для хранения пунктов в списке

#include <GuiComboBoxEx.au3>
_GUICtrlComboBoxEx_InitStorage($hWnd, $iNum, $iBytes)

Параметры

$hWnd Дескриптор элемента
$iNum Количество добавляемых пунктов
$iBytes Объем памяти, выделенной для пункта, в байтах

Возвращаемое значение

Успех:Общее количество пунктов, для которых была предварительно выделена память
Ошибка:$CB_ERRSPACE

Примечания

Помогает ускорить инициализацию ComboBoxes, который имеет большое количество пунктов (более 100).

Для оценки вы можете использовать параметры $iNum и $iBytes.
Если выделено сверх меры, то дополнительная память выделяется.
Если выделено недостаточно, то используется обычное выделение памяти для пунктов, которые превышают требуемое количество.

См. также

_GUICtrlComboBoxEx_AddDir, _GUICtrlComboBoxEx_AddString, _GUICtrlComboBoxEx_InsertString

Пример

#include <GuiComboBoxEx.au3>
#include <GUIConstantsEx.au3>

$Debug_CB = False ; Проверяет ClassName передаваемый в ComboBox/ComboBoxEx функции. Установите True и используйте дескриптор от другого элемента, чтобы увидеть как это работает

_Main()

Func _Main()
    Local $hGUI, $hCombo

    ; Создаёт GUI
    $hGUI = GUICreate("Выделяет память", 400, 300)
    $hCombo = _GUICtrlComboBoxEx_Create ($hGUI, "", 2, 2, 396, 296, $CBS_SIMPLE)
    GUISetState()

    MsgBox(4160, "Информация", "Выделяет память для: " & _GUICtrlComboBoxEx_InitStorage ($hCombo, 150, 300) & " пунктов")
    _GUICtrlComboBoxEx_BeginUpdate ($hCombo)

    For $x = 0 To 149
        _GUICtrlComboBoxEx_AddString ($hCombo, StringFormat("%03d : Рандомная строка", Random(1, 100, 1)))
    Next
    _GUICtrlComboBoxEx_EndUpdate ($hCombo)

    Do
    Until GUIGetMsg() = $GUI_EVENT_CLOSE
EndFunc   ;==>_Main