Функция _GUICtrlButton_SetFocus

         Описание функции

_GUICtrlButton_SetFocus

Устанавливает фокус на указанную кнопку

#include <GuiButton.au3>
_GUICtrlButton_SetFocus($hWnd [, $fFocus = True])

Параметры

$hWnd Дескриптор или идентификатор элемента
$fFocus [необязательный] This parameter can be one of the following values:
    True - Устанавливает фокус на кнопку
    False - Убирает фокус с кнопки

Возвращаемое значение

Успех:Возвращает True
Ошибка:Возвращает False

См. также

_GUICtrlButton_GetFocus

Пример

#include <GUIConstantsEx.au3>
#include <GuiButton.au3>
#include <WindowsConstants.au3>

Global $iMemo

_Main()

Func _Main()
    Local $rdo, $rdo2, $chk

    GUICreate("Устанавливает фокус", 400, 400)
    $iMemo = GUICtrlCreateEdit("", 119, 10, 276, 374, $WS_VSCROLL)
    GUICtrlSetFont($iMemo, 9, 400, 0, "Courier New")

    $rdo = GUICtrlCreateRadio("Радио1", 10, 10, 90, 50)
    _GUICtrlButton_SetFocus($rdo)

    $rdo2 = GUICtrlCreateRadio("Радио2", 10, 60, 90, 50)
    _GUICtrlButton_SetCheck($rdo2)

    $chk = GUICtrlCreateCheckbox("Check1", 10, 120, 90, 50, BitOR($BS_AUTO3STATE, $BS_NOTIFY))
    _GUICtrlButton_SetCheck($chk, $BST_INDETERMINATE)

    GUISetState()

    MemoWrite(StringFormat("Фокус Радио1: %s", _GUICtrlButton_GetFocus($rdo)))
    MemoWrite(StringFormat("Фокус Радио2: %s", _GUICtrlButton_GetFocus($rdo2)))
    MemoWrite(StringFormat("Фокус Check1: %s", _GUICtrlButton_GetFocus($chk)))

    While 1
        Switch GUIGetMsg()
            Case $GUI_EVENT_CLOSE
                ExitLoop
        EndSwitch
    WEnd

    Exit
EndFunc   ;==>_Main

; Записывает строку в элемент для заметок
Func MemoWrite($sMessage)
    GUICtrlSetData($iMemo, $sMessage & @CRLF, 1)
EndFunc   ;==>MemoWrite