Функция GUICtrlCreateCheckbox

GUICtrlCreateCheckbox

Создаёт Checkbox в GUI.

GUICtrlCreateCheckbox ( "text", left, top [, width [, height [, style = -1 [, exStyle = -1 ]]]] )

Параметры

text	Текст checkbox.
left	Координата левого края. Если -1 - тогда координата в соответствии с GUICoordMode.
top	Координата верхнего края. Если -1 - тогда координата в соответствии с GUICoordMode.
width	[необязательный] Ширина элемента (по умолчанию устанавливается по длине текста).
height	[необязательный] Высота элемента (по умолчанию устанавливается по высоте текста).
style	[необязательный] Стиль элемента. Смотрите Стили элементов GUI в приложении. -1 - по умолчанию : $BS_AUTOCHECKBOX. принудительный стиль : $WS_TABSTOP и $BS_AUTOCHECKBOX, если не определены другие стили checkbox.
exStyle	[необязательный] Расширенный стиль элемента. Смотрите таблицу расширенных стилей.

Возвращаемое значение

Успех:	Возвращает идентификатор (controlID) нового элемента.
Ошибка:	Возвращает 0.

Примечания

Для получения параметров элемента смотрите GUICtrlRead.
Чтобы установить или изменить параметры элемента смотрите GUICtrlUpdate....

Checkbox может отображать иконку или рисунок, для этого используйте стили $BS_ICON или $BS_BITMAP. Используйте GUICtrlSetImage для установки рисунка.

Чтобы объединить стили со стилем по умолчанию используйте BitOR($GUI_SS_DEFAULT_CHECKBOX, новый стиль,...).

Чтобы использовать параметры, указанные выше, вы должны включить в ваш скрипт #include <ButtonConstants.au3>.

По умолчанию стиль изменения размеров $GUI_DOCKHEIGHT (не изменяется высота).

См. также

GUICoordMode (Опция), GUICtrlUpdate..., GUIGetMsg

Пример

#include <GUIConstantsEx.au3>
#include <ButtonConstants.au3>

Local $nCh1, $nCh2, $nCh3, $nCh4, $nCh5, $nCh6, $msg
GUICreate("My GUI Checkbox") ; Создаёт окно в центре экрана

$nCh1 = GUICtrlCreateCheckbox("Checkbox 1", 10, 10, 120, 20)

$nCh2 = GUICtrlCreateCheckbox("Этот Checkbox имеет три состояния", 10, 30, -1, 20, $BS_AUTO3STATE)

GUICtrlCreateLabel('Checkbox в виде кнопок', 10, 85, -1, 17)
$nCh3 = GUICtrlCreateCheckbox("-", 10, 105, 40, 40, $BS_PUSHLIKE + $BS_ICON)
GUICtrlSetImage(-1, "shell32.dll", 48, 1)

$nCh4 = GUICtrlCreateCheckbox("-", 60, 115, 24, 24, $BS_PUSHLIKE + $BS_ICON)
GUICtrlSetImage(-1, "shell32.dll", 24, 0)

$nCh5 = GUICtrlCreateCheckbox("-", 10, 155, 40, 40, $BS_PUSHLIKE + $BS_ICON + $BS_AUTO3STATE)
GUICtrlSetImage(-1, "shell32.dll", 7, 1)

$nCh6 = GUICtrlCreateCheckbox("-", 10, 200, 160, 160, $BS_PUSHLIKE + $BS_BITMAP)
GUICtrlSetImage(-1, "oemlogo.bmp")

GUISetState() ; показывает созданное окно

; Запускается цикл опроса GUI до тех пор пока окно не будет закрыто
While 1
$msg = GUIGetMsg()
If $msg = $GUI_EVENT_CLOSE Then ExitLoop
WEnd