Функция _GUICtrlButton_SetCheck

         Описание функции

_GUICtrlButton_SetCheck

Устанавливает флажок состояния радиокнопки или checkbox

#include <GuiButton.au3>
_GUICtrlButton_SetCheck($hWnd [, $iState = $BST_CHECKED])

Параметры

$hWnd Дескриптор или идентификатор элемента
$iState [необязательный] Флажок состояния. Этот параметр может быть одним из следующих значений:
    $BST_CHECKED - Устанавливает состояние "отмеченный".
    $BST_INDETERMINATE - Устанавливает третье состояние, указывающее неопределённое состояние (применяется только когда кнопка имеет стиль $BS_3STATE или $BS_AUTO3STATE).
    $BST_UNCHECKED - Устанавливает состояние "не отмеченный".

Примечания

Функция _GUICtrlButton_SetCheck не имеет эффекта на push кнопки.

См. также

_GUICtrlButton_GetCheck, _GUICtrlButton_GetState, _GUICtrlButton_SetState

См. также

Искать BCM_GETTEXTMARGIN в библиотеке MSDN

Пример

#include <GUIConstantsEx.au3>
#include <GuiButton.au3>
#include <WindowsConstants.au3>

Global $iMemo

_Main()

Func _Main()
    Local $rdo, $rdo2, $chk

    GUICreate("Устанавливает флажок", 400, 400)
    $iMemo = GUICtrlCreateEdit("", 119, 10, 276, 374, $WS_VSCROLL)
    GUICtrlSetFont($iMemo, 9, 400, 0, "Courier New")

    $rdo = GUICtrlCreateRadio("Радио1", 10, 10, 90, 50)

    $rdo2 = GUICtrlCreateRadio("Радио2", 10, 60, 90, 50)
    _GUICtrlButton_SetCheck($rdo2)
    _GUICtrlButton_SetFocus($rdo2) ; устанавливает фокус, и показывает что это не влияет на _GUICtrlButton_GetCheck

    $chk = GUICtrlCreateCheckbox("Check1", 10, 120, 90, 50, BitOR($BS_AUTO3STATE, $BS_NOTIFY))
    _GUICtrlButton_SetCheck($chk, $BST_INDETERMINATE)

    GUISetState()

    MemoWrite("Состояние Радио1: " & _ExplainCheckState(_GUICtrlButton_GetCheck($rdo)) & @CRLF)
    MemoWrite("Состояние Радио2: " & _ExplainCheckState(_GUICtrlButton_GetCheck($rdo2)) & @CRLF)
    MemoWrite("Состояние Check1: " & _ExplainCheckState(_GUICtrlButton_GetCheck($chk)) & @CRLF)


    While 1
        Switch GUIGetMsg()
            Case $GUI_EVENT_CLOSE
                ExitLoop
        EndSwitch
    WEnd

    Exit
EndFunc   ;==>_Main

; Записывает строку в элемент для заметок
Func MemoWrite($sMessage)
    GUICtrlSetData($iMemo, $sMessage & @CRLF, 1)
EndFunc   ;==>MemoWrite

Func _ExplainCheckState($iState)
    Switch $iState
        Case $BST_CHECKED
            Return "Отмечена"
        Case $BST_INDETERMINATE
            Return "Серая, третье состояние, указывающее неопределённое состояние (применяется только когда кнопка имеет стиль $BS_3STATE или $BS_AUTO3STATE)."
        Case $BST_UNCHECKED
            Return "Не отмечена"
    EndSwitch
EndFunc   ;==>_ExplainCheckState