Функция _GUICtrlAVI_Play

         Описание функции

_GUICtrlAVI_Play

Воспроизводит клип AVI в элементе

#include <GuiAVI.au3>
_GUICtrlAVI_Play($hWnd [, $iFrom = 0 [, $iTo = -1 [, $iRepeat = -1]]])

Параметры

$hWnd Дескриптор или идентификатор элемента
$iFrom [необязательный] Индекс кадра, от которого начинается воспроизведение, отсчёт от 0. Значение должно быть меньше, чем 65536. Значение 0 означает начать с первого кадра в клипе.
$iTo [необязательный] Индекс кадра, в котором заканчивается воспроизведение, отсчёт от 0. Значение должно быть меньше, чем 65536. Значение -1 означает последний кадр клипа.
$iRepeat [необязательный] Количество повторов воспроизведения клипа. Значение -1 означает повторять бесконечно.

Возвращаемое значение

Успех:Возвращает True
Ошибка:Возвращает False

Примечания

Элемент воспроизводит клип в фоне, при этом команды скрипта продолжают выполнятся.

См. также

_GUICtrlAVI_Stop, _GUICtrlAVI_Seek

Пример

#include <GUIConstantsEx.au3>
#include <GuiAVI.au3>

$Debug_AVI = False ; Проверяет ClassName передаваемый в AVI функции. Установите True и используйте дескриптор от другого элемента, чтобы увидеть как это работает

Global $hAVI

_Example_Internal()
_Example_External()

Func _Example_Internal()
    Local $btn_start, $btn_stop

    ; Создаёт GUI
    GUICreate("Воспроизводит AVI", 300, 200)
    $hAVI = GUICtrlCreateAvi (@SystemDir & "\shell32.dll",160, 10,10)
    $btn_start = GUICtrlCreateButton ("Старт",50,150,70,22)
    $btn_stop  = GUICtrlCreateButton ("Стоп",150,150,70,22)
    GUISetState()

    ; Цикл выполняется, пока окно не будет закрыто
    While 1
        Switch GUIGetMsg()
            Case $GUI_EVENT_CLOSE
                ExitLoop
            Case $btn_start
                ; Воспроизводит клип AVI
                _GUICtrlAVI_Play($hAVI)
            Case $btn_stop
                ; Останавливает воспроизведение клипа
                _GUICtrlAVI_Stop($hAVI)
        EndSwitch
    WEnd

    ; Закрывает AVI
    _GUICtrlAVI_Close($hAVI)

    GUIDelete()
EndFunc   ;==>_Main

Func _Example_External()
    Local $hGUI, $btn_start, $btn_stop

    ; Создаёт GUI
    $hGUI = GUICreate("(UDF) Воспроизводит AVI", 300, 200)
    $hAVI = _GUICtrlAVI_Create ($hGUI, @SystemDir & "\Shell32.dll", 160, 10, 10)
    $btn_start = GUICtrlCreateButton ("Старт",50,150,70,22)
    $btn_stop  = GUICtrlCreateButton ("Стоп",150,150,70,22)
    GUISetState()

    ; Цикл выполняется, пока окно не будет закрыто
    While 1
        Switch GUIGetMsg()
            Case $GUI_EVENT_CLOSE
                ExitLoop
            Case $btn_start
                ; Воспроизводит клип AVI
                _GUICtrlAVI_Play($hAVI)
            Case $btn_stop
                ; Останавливает воспроизведение клипа
                _GUICtrlAVI_Stop($hAVI)
        EndSwitch
    WEnd

    ; Закрывает AVI
    _GUICtrlAVI_Close($hAVI)

    GUIDelete()
EndFunc   ;==>_Main