Функция GUICtrlCreateAvi

GUICtrlCreateAvi

Создает элемент AVI видео для GUI.

GUICtrlCreateAvi ( filename, subfileid, left, top [, width [, height [, style = -1 [, exStyle = -1 ]]]] )

Параметры

filename	Имя видео файла. Поддерживаются только *.avi файлы.
subfileid	Номер используемого ресурса. Если файл содержит только один видео ресурс, то использовать 0.
left	Координата левого края. Если -1 - тогда координата в соответствии с GUICoordMode.
top	Координата верхнего края. Если -1 - тогда координата в соответствии с GUICoordMode.
width	[необязательный] Ширина элемента (по умолчанию предыдущее значение).
height	[необязательный] Высота элемента (по умолчанию предыдущее значение).
style	[необязательный] Стиль элемента. Смотрите Стили элементов GUI в приложении. -1 - по умолчанию : $ACS_TRANSPARENT $ACS_TRANSPARENT всегда используется, если не указан $ACS_NONTRANSPARENT.
exStyle	[необязательный] Расширенный стиль элемента. Смотрите таблицу расширенных стилей.

Возвращаемое значение

Успех:	Возвращает идентификатор (controlID) нового элемента.
Ошибка:	Возвращает 0.

Примечания

Для получения параметров элемента смотрите GUICtrlRead.
Чтобы установить или изменить параметры элемента смотрите GUICtrlUpdate....

Чтобы воспроизвести видео, сразу при создании элемента, используйте стиль $ACS_AUTOPLAY.
Вы можете запускать и останавливать видео, установив состояние 1 или 0, используя GUICtrlSetState. Смотрите пример.

Чтобы объединить стили со стилем по умолчанию используйте BitOR($GUI_SS_DEFAULT_AVI, новый стиль,...).

Чтобы использовать параметры, указанные выше, вы должны включить в ваш скрипт #include <AVIConstants.au3>.

По умолчанию стиль изменения размеров $GUI_DOCKSIZE (не изменяется размер).

См. также

GUICoordMode (Опция), GUICtrlUpdate..., GUIGetMsg

Пример

#include <GUIConstantsEx.au3>

Local $iAvi, $iBtnStart, $iBtnStop, $msg

GUICreate("Анимация AVI в GUI", 300, 200)
$iAvi = GUICtrlCreateAvi(@SystemDir & "\shell32.dll", 165, 10, 10)

$iBtnStart = GUICtrlCreateButton("Старт", 50, 150, 90, 28)
$iBtnStop = GUICtrlCreateButton("Стоп", 160, 150, 90, 28)

GUISetState()

; Запускается цикл опроса GUI до тех пор пока окно не будет закрыто
While 1
$msg = GUIGetMsg()

Switch $msg
Case $GUI_EVENT_CLOSE
ExitLoop

Case $iBtnStart
GUICtrlSetState($iAvi, 1)

Case $iBtnStop
GUICtrlSetState($iAvi, 0)

EndSwitch
WEnd