Описание функции Описание функции
_GUICtrlAVI_Create
Создает элемент AVI
#include <GuiAVI.au3>
_GUICtrlAVI_Create($hWnd [, $sFile = "" [, $subfileid = -1 [, $iX = 0 [, $iY = 0 [, $iWidth = 0 [, $iHeight = 0 [, $iStyle = 0x00000006 [, $iExStyle = 0x00000000]]]]]]]])
Параметры
| $hWnd | Дескриптор родительского окна или окна владельца |
| $sFile |
[необязательный] Путь к видео-файлу. Поддерживаются только avi-файлы |
| $subfileid |
[необязательный] Номер ресурса, если используется dll-файл. |
| $iX |
[необязательный] Координата левого края |
| $iY |
[необязательный] Координата верхнего края |
| $iWidth |
[необязательный] Ширина элемента |
| $iHeight |
[необязательный] Высота элемента |
| $iStyle |
[необязательный] Стиль элемента: $ACS_CENTER - Центрирует анимацию в анимационном элементе окна $ACS_TRANSPARENT - Создает элемент с прозрачным фоном $ACS_AUTOPLAY - Запуск воспроизведения анимации, как только клип AVI открыт $ACS_TIMER - The control plays the clip without creating a thread По умолчанию: $ACS_TRANSPARENT, $ACS_AUTOPLAY Принудительный стиль : $WS_CHILD, $WS_VISIBLE |
| $iExStyle |
[необязательный] Расширенный стиль элемента |
Возвращаемое значение
| Успех: | Возвращает дескриптор элемента AVI |
| Ошибка: | Возвращает 0 |
Примечания
Эта функция предназначена для опытных пользователей и для изучения того, как элемент работает.См. также
_GUICtrlAVI_DestroyПример
#include <GUIConstantsEx.au3>
#include <GuiAVI.au3>
#include <WindowsConstants.au3>
$Debug_AVI = False ; Проверяет ClassName передаваемый в AVI функции. Установите True и используйте дескриптор от другого элемента, чтобы увидеть как это работает
Global $hAVI
_Example1()
_Example2()
Func _Example1()
Local $Wow64 = ""
If @AutoItX64 Then $Wow64 = "\Wow6432Node"
Local $hGUI, $sFile = RegRead("HKEY_LOCAL_MACHINE\SOFTWARE" & $Wow64 & "\AutoIt v3\AutoIt", "InstallDir") & "\Examples\GUI\SampleAVI.avi"
; Создаёт GUI
$hGUI = GUICreate("(UDF 1) Создаёт AVI", 300, 100)
$hAVI = _GUICtrlAVI_Create ($hGUI, $sFile, -1, 10, 10)
GUISetState()
GUIRegisterMsg($WM_COMMAND, "WM_COMMAND")
; Воспроизводит пример AutoIt AVI
_GUICtrlAVI_Play ($hAVI)
; Цикл выполняется, пока окно не будет закрыто
Do
Until GUIGetMsg() = $GUI_EVENT_CLOSE
; Закрывает AVI
_GUICtrlAVI_Close ($hAVI)
GUIDelete()
EndFunc ;==>_Example1
Func _Example2()
Local $hGUI
; Создаёт GUI
$hGUI = GUICreate("(UDF 2) Создаёт AVI", 300, 100)
$hAVI = _GUICtrlAVI_Create ($hGUI, @SystemDir & "\Shell32.dll", 150, 10, 10)
GUISetState()
GUIRegisterMsg($WM_COMMAND, "WM_COMMAND")
; Воспроизводит пример AutoIt AVI
_GUICtrlAVI_Play ($hAVI)
; Цикл выполняется, пока окно не будет закрыто
Do
Until GUIGetMsg() = $GUI_EVENT_CLOSE
; Закрывает AVI
_GUICtrlAVI_Close ($hAVI)
GUIDelete()
EndFunc ;==>_Example2
Func WM_COMMAND($hWnd, $iMsg, $iwParam, $ilParam)
#forceref $hWnd, $iMsg
Local $hWndFrom, $iIDFrom, $iCode
$hWndFrom = $ilParam
$iIDFrom = BitAND($iwParam, 0xFFFF) ; младшее слово
$iCode = BitShift($iwParam, 16) ; старшее слово
Switch $hWndFrom
Case $hAVI
Switch $iCode
Case $ACN_START ; Уведомление от элемента AVI родительскому окну, что началось воспроизведение клипа
_DebugPrint("$ACN_START" & @LF & "--> hWndFrom:" & @TAB & $hWndFrom & @LF & _
"-->IDFrom:" & @TAB & $iIDFrom & @LF & _
"-->Code:" & @TAB & $iCode)
; Нет возвращаемых значений
Case $ACN_STOP ; Уведомление от элемента AVI родительскому окну, что воспроизведение клипа остановлено
_DebugPrint("$ACN_STOP" & @LF & "--> hWndFrom:" & @TAB & $hWndFrom & @LF & _
"-->IDFrom:" & @TAB & $iIDFrom & @LF & _
"-->Code:" & @TAB & $iCode)
; Нет возвращаемых значений
EndSwitch
EndSwitch
Return $GUI_RUNDEFMSG
EndFunc ;==>WM_COMMAND
Func _DebugPrint($s_text, $line = @ScriptLineNumber)
ConsoleWrite( _
"!===========================================================" & @LF & _
"+======================================================" & @LF & _
"-->Строка(" & StringFormat("%04d", $line) & "):" & @TAB & $s_text & @LF & _
"+======================================================" & @LF)
EndFunc ;==>_DebugPrint