Функция _GDIPlus_PenGetDashCap

         Описание функции

_GDIPlus_PenGetDashCap

Возвращает стиль карандаша, определяющий форму концов штриха и пунктира

#include <GDIPlus.au3>
_GDIPlus_PenGetDashCap($hPen)

Параметры

$hPen Дескриптор объекта Карандаш

Возвращаемое значение

Успех:Стиль концов штриха и пунктира:
$GDIP_DASHCAPFLAT - квадратные концы с обоих сторон штриха и пунктира
$GDIP_DASHCAPROUND - круглые концы с обоих сторон штриха и пунктира
$GDIP_DASHCAPTRIANGLE - треугольные концы с обоих сторон штриха и пунктира
Ошибка:Возвращает -1 и устанавливает @error

См. также

_GDIPlus_PenSetDashCap

См. также

Искать GdipGetPenDashCap197819 в библиотеке MSDN

Пример

#include <GUIConstantsEx.au3>
#include <GDIPlus.au3>

_Main()

Func _Main()
    Local $hGUI, $hGraphic, $hPen

    ; Создаёт GUI
    $hGUI = GUICreate("GDI+", 400, 300)
    GUISetState()

    ; Создаёт ресурсы
    _GDIPlus_Startup ()
    $hGraphic = _GDIPlus_GraphicsCreateFromHWND ($hGUI)
    $hPen = _GDIPlus_PenCreate (0xFF000000, 8)
    _GDIPlus_PenSetDashStyle ($hPen, $GDIP_DASHSTYLEDASHDOT)
    _GDIPlus_PenSetDashCap ($hPen, $GDIP_DASHCAPTRIANGLE)

    ; Показывает стиль
    MsgBox(4096, "Информация", "Стиль концов штриховой линии: " & _GDIPlus_PenGetDashCap ($hPen))

    ; Рисует линию
    _GDIPlus_GraphicsDrawLine ($hGraphic, 10, 150, 390, 150, $hPen)

    ; Цикл выполняется, пока окно не будет закрыто
    Do
    Until GUIGetMsg() = $GUI_EVENT_CLOSE

    ; Очищает ресурсы
    _GDIPlus_PenDispose ($hPen)
    _GDIPlus_GraphicsDispose ($hGraphic)
    _GDIPlus_ShutDown ()

EndFunc   ;==>_Main