Функция _GDIPlus_Startup

         Описание функции

_GDIPlus_Startup

Инициализация Microsoft Windows GDI+

#include <GDIPlus.au3>
_GDIPlus_Startup()

Возвращаемое значение

Успех:Возвращает True
Ошибка:Возвращает False

Примечания

Перед созданием любого объекта GDI+ необходимо вызвать _GDIPlus_Startup. GDI+ необходимо распространять для приложений, которые запускаются в операционных системах Microsoft Windows 2000.

См. также

_GDIPlus_Shutdown

См. также

Искать GdiplusStartup в библиотеке MSDN

Пример

#include <GUIConstantsEx.au3>
#include <GDIPlus.au3>
#include <ScreenCapture.au3>
#include <WinAPI.au3>

_Main()

Func _Main()
    Local $hGUI, $hBMP, $hBitmap, $hGraphic

    ; Захватывает левый верхний угол экрана
    $hBMP = _ScreenCapture_Capture ("", 0, 0, 400, 300)

    ; Создаёт GUI
    $hGUI = GUICreate("GDI+", 400, 300)
    GUISetState()

    ; Инициализация библиотеки GDI+
    _GDIPlus_Startup ()

    ; Рисует bitmap в GUI
    $hBitmap = _GDIPlus_BitmapCreateFromHBITMAP ($hBMP)
    $hGraphic = _GDIPlus_GraphicsCreateFromHWND ($hGUI)
    _GDIPlus_GraphicsDrawImage ($hGraphic, $hBitmap, 0, 0)

    ; Очищает ресурсы
    _GDIPlus_GraphicsDispose ($hGraphic)
    _GDIPlus_ImageDispose ($hBitmap)
    _WinAPI_DeleteObject ($hBMP)

    ; Закрывает библиотеку GDI+
    _GDIPlus_ShutDown ()

    ; Цикл выполняется, пока окно не будет закрыто
    Do
    Until GUIGetMsg() = $GUI_EVENT_CLOSE


EndFunc   ;==>_Main