Функция _GDIPlus_BitmapCreateFromHBITMAP

         Описание функции

_GDIPlus_BitmapCreateFromHBITMAP

Создает объект Bitmap используя дескриптор Bitmap

#include <GDIPlus.au3>
_GDIPlus_BitmapCreateFromHBITMAP($hBmp [, $hPal = 0])

Параметры

$hBmp Дескриптор HBITMAP
$hPal [необязательный] Дескриптор HPALETTE (палитры)

Возвращаемое значение

Успех:Возвращает дескриптор Bitmap объекта
Ошибка:Возвращает 0

Примечания

При завершении использования объекта Bitmap, необходимо вызвать функцию _WinAPI_DeleteObject, чтобы освободить ресурсы.

См. также

_WinAPI_DeleteObject

См. также

Искать GdipCreateBitmapFromHBITMAP в библиотеке MSDN

Пример

#include <GUIConstantsEx.au3>
#include <GDIPlus.au3>
#include <ScreenCapture.au3>

_Main()

Func _Main()
    Local $hGUI, $hBMP, $hBitmap, $hGraphic

    ; Захватывает левый верхний угол экрана
    $hBMP = _ScreenCapture_Capture ("", 0, 0, 400, 300)

    ; Создаёт GUI
    $hGUI = GUICreate("GDI+", 400, 300)
    GUISetState()

    ; Инициализация библиотеки GDI+
    _GDIPlus_Startup ()

    ; Рисует bitmap в GUI
    $hBitmap = _GDIPlus_BitmapCreateFromHBITMAP ($hBMP)
    $hGraphic = _GDIPlus_GraphicsCreateFromHWND ($hGUI)
    _GDIPlus_GraphicsDrawImage ($hGraphic, $hBitmap, 0, 0)

    ; Очищает ресурсы
    _GDIPlus_GraphicsDispose ($hGraphic)
    _GDIPlus_BitmapDispose ($hBitmap)
    _WinAPI_DeleteObject ($hBMP)

    ; Закрывает библиотеку GDI+
    _GDIPlus_ShutDown ()

    ; Цикл выполняется, пока окно не будет закрыто
    Do
    Until GUIGetMsg() = $GUI_EVENT_CLOSE


EndFunc   ;==>_Main