Функция _GDIPlus_PenCreate

         Описание функции

_GDIPlus_PenCreate

Создаёт объект Карандаш

#include <GDIPlus.au3>
_GDIPlus_PenCreate([$iARGB = 0xFF000000 [, $nWidth = 1 [, $iUnit = 2]]])

Параметры

$iARGB [необязательный] Компоненты цвета карандаша - альфа (прозрачность), красный, зелёный, синий
$nWidth [необязательный] Толщина карандаша, размерность единицы которого указана в параметре $iUnit
$iUnit [необязательный] Единица измерения толщины карандаша:
    0 - World coordinates, a nonphysical unit
    1 - Display units
    2 - Единица в 1 пиксель
    3 - Единица 1 точка или 1/72 дюйма
    4 - Единица 1 дюйм
    5 - Единица 1/300 дюйма
    6 - Единица 1 мм

Возвращаемое значение

Успех:Возвращает дескриптор объекта Карандаш
Ошибка:Возвращает 0

Примечания

Когда вы закончили использование объекта Карандаш, вызовите _GDIPlus_PenDispose, чтобы освободить ресурсы

См. также

_GDIPlus_PenDispose

См. также

Искать GdipCreatePen1 в библиотеке MSDN

Пример

#include <GUIConstantsEx.au3>
#include <GDIPlus.au3>

_Main()

Func _Main()
    Local $hGUI, $hGraphic, $hPen

    ; Создаёт GUI
    $hGUI = GUICreate("GDI+", 400, 300)
    GUISetState()

    ; Рисует линию
    _GDIPlus_Startup ()
    $hGraphic = _GDIPlus_GraphicsCreateFromHWND ($hGUI)
    $hPen = _GDIPlus_PenCreate ()
    _GDIPlus_GraphicsDrawLine ($hGraphic, 10, 150, 390, 150, $hPen)

    ; Цикл выполняется, пока окно не будет закрыто
    Do
    Until GUIGetMsg() = $GUI_EVENT_CLOSE

    ; Очищает ресурсы
    _GDIPlus_PenDispose ($hPen)
    _GDIPlus_GraphicsDispose ($hGraphic)
    _GDIPlus_ShutDown ()

EndFunc   ;==>_Main