Функция _GDIPlus_GraphicsDrawLine

         Описание функции

_GDIPlus_GraphicsDrawLine

Рисует линию

#include <GDIPlus.au3>
_GDIPlus_GraphicsDrawLine($hGraphics, $iX1, $iY1, $iX2, $iY2 [, $hPen = 0])

Параметры

$hGraphics Дескриптор графического объекта
$iX1 X-координата начальной точки линии
$iY1 Y-координата начальной точки линии
$iX2 X-координата конечной точки линии
$iY2 Y-координата конечной точки линии
$hPen [необязательный] Дескриптор объекта карандаша, который используется для рисования линии. Если 0, то чёрная линия шириной 1 пиксель.

Возвращаемое значение

Успех:Возвращает True
Ошибка:Возвращает False

См. также

Искать GdipDrawLineI в библиотеке MSDN

Пример

#include <GUIConstantsEx.au3>
#include <GDIPlus.au3>

_Main()

Func _Main()
    Local $hGUI, $hGraphic, $hPen

    ; Создаёт GUI
    $hGUI = GUICreate("GDI+", 400, 300)
    GUISetState()

    ; Рисует линию
    _GDIPlus_Startup ()
    $hGraphic = _GDIPlus_GraphicsCreateFromHWND ($hGUI)
    $hPen = _GDIPlus_PenCreate ()
    _GDIPlus_GraphicsDrawLine ($hGraphic, 10, 150, 390, 150, $hPen)

    ; Цикл выполняется, пока окно не будет закрыто
    Do
    Until GUIGetMsg() = $GUI_EVENT_CLOSE

    ; Очищает ресурсы
    _GDIPlus_PenDispose ($hPen)
    _GDIPlus_GraphicsDispose ($hGraphic)
    _GDIPlus_Shutdown ()

EndFunc   ;==>_Main