Функция _GDIPlus_ArrowCapDispose

         Описание функции

_GDIPlus_ArrowCapDispose

Release an adjustable arrow line cap object

#include <GDIPlus.au3>
_GDIPlus_ArrowCapDispose($hCap)

Параметры

$hCap Handle to an adjustable arrow line cap object

Возвращаемое значение

Успех:Возвращает True
Ошибка:Возвращает False

См. также

_GDIPlus_ArrowCapCreate

См. также

Искать GdipDeleteCustomLineCap в библиотеке MSDN

Пример

#include <GUIConstantsEx.au3>
#include <GDIPlus.au3>

_Main()

Func _Main()
    Local $hGUI, $hGraphic, $hPen, $hEndCap

    ; Создаёт GUI
    $hGUI = GUICreate("GDI+", 400, 300)
    GUISetState()

    ; Создаёт ресурсы
    _GDIPlus_Startup ()
    $hGraphic = _GDIPlus_GraphicsCreateFromHWND ($hGUI)
    $hPen = _GDIPlus_PenCreate (0xFF000000, 2)
    $hEndCap = _GDIPlus_ArrowCapCreate (3, 6)
    _GDIPlus_PenSetCustomEndCap ($hPen, $hEndCap)

    ; Show pen end cap
    MsgBox(4096, "Информация", "Pen end cap: 0x" & Hex(_GDIPlus_PenGetCustomEndCap ($hPen)))

    ; Рисует стрелки
    _GDIPlus_GraphicsDrawLine ($hGraphic, 10, 120, 390, 120, $hPen)
    _GDIPlus_PenSetWidth ($hPen, 4)
    _GDIPlus_GraphicsDrawLine ($hGraphic, 10, 150, 390, 150, $hPen)
    _GDIPlus_PenSetWidth ($hPen, 6)
    _GDIPlus_GraphicsDrawLine ($hGraphic, 10, 180, 390, 180, $hPen)

    ; Цикл выполняется, пока окно не будет закрыто
    Do
    Until GUIGetMsg() = $GUI_EVENT_CLOSE

    ; Очищает ресурсы
    _GDIPlus_ArrowCapDispose ($hEndCap)
    _GDIPlus_PenDispose ($hPen)
    _GDIPlus_GraphicsDispose ($hGraphic)
    _GDIPlus_Shutdown ()
EndFunc   ;==>_Main