Функция GUICtrlSetResizing

GUICtrlSetResizing

Определяет поведение элементов при изменении размеров GUI-окна

GUICtrlSetResizing ( controlID, resizing )

Параметры

controlID	Идентификатор элемента возвращаемый функцией GUICtrlCreate....
resizing	Смотрите Таблицу значений для использования (сложить несколько значений, если потребуется).

Возвращаемое значение

Успех:	Возвращает 1.
Ошибка:	Возвращает 0.

Примечания

Реакция поведения элементов, при изменении GUI-окна в размерах определяется текущей функцией. Чтобы изменить размер GUI-окна используйте стили $WS_SIZEBOX и $WS_SYSMENU. Смотрите GUICreate.

Таблица значений

Стиль	Величина	Поведение
$GUI_DOCKAUTO	1	изменяется размер и отступы пропорционально новым размерам окна
$GUI_DOCKLEFT	2	левый отступ не изменяется
$GUI_DOCKRIGHT	4	правый отступ не изменяется
$GUI_DOCKHCENTER	8	не перемещается относительно горизонтального центра

$GUI_DOCKTOP	32	верхний отступ не изменяется
$GUI_DOCKBOTTOM	64	нижний отступ не изменяется
$GUI_DOCKVCENTER	128	не перемещается относительно вертикального центра

$GUI_DOCKWIDTH	256	ширина не изменяется
$GUI_DOCKHEIGHT	512	высота не изменяется
		Объединённые стили
$GUI_DOCKSIZE	768	(256+512) размер не изменяется
$GUI_DOCKMENUBAR	544	(512+32) элементы остаются в верхней части окна и без изменения высоты
$GUI_DOCKSTATEBAR	576	(512+64) элементы остаются в нижней части окна и без изменения высоты
$GUI_DOCKALL	802	(2+32+256+512) элемент не изменяется и не перемещается
$GUI_DOCKBORDERS	102	(2+4+32+64) размеры изменяются на величину изменения окна.

По умолчанию изменение размеров происходит согласно документации элемента.
Для всех элементов можно установить поведение по умолчанию с помощью GUIResizeMode (Опция).

Событие автоматического изменения размеров может быть отключено, если GUIEventOptions (Опция) имеет значение 1.

См. также

GUIResizeMode (Опция), GUIEventOptions (Опция), GUICtrlCreate...

Пример

#include <GUIConstantsEx.au3>
#include <WindowsConstants.au3>
#include <EditConstants.au3>

Opt("GUIResizeMode", 2 + 32 + 256 + 512) ; =802 - устанавливает стандартное поведение всех элементов в GUI, для которых не определёно поведение с помощью GUICtrlSetResizing.

Example()

Func Example()
Local $iEdit, $iBtnOk, $iBtnCancel, $msg

Opt("GUICoordMode", 2)
GUICreate("Мой InputBox", 190, 114, -1, -1, $WS_SIZEBOX + $WS_SYSMENU) ; установите стиль позволяющий изменять размер

GUICtrlCreateLabel("Введите текст", 8, 7) ; добавляет текст информации
GUICtrlSetResizing(-1, $GUI_DOCKLEFT + $GUI_DOCKTOP)

$iEdit = GUICtrlCreateInput("Default", -1, 3, 175, 20, $ES_PASSWORD) ; добавляет поле ввода
GUICtrlSetState($iEdit, $GUI_FOCUS)
GUICtrlSetResizing($iEdit, $GUI_DOCKBOTTOM + $GUI_DOCKHEIGHT)

$iBtnOk = GUICtrlCreateButton("OK", -1, 3, 75, 24) ; добавляет кнопку OK
GUICtrlSetResizing($iBtnOk, $GUI_DOCKBOTTOM + $GUI_DOCKSIZE + $GUI_DOCKHCENTER)

$iBtnCancel = GUICtrlCreateButton("Отмена", 25, -1) ; добавляет кнопку отмены
GUICtrlSetResizing($iBtnCancel, $GUI_DOCKBOTTOM + $GUI_DOCKSIZE + $GUI_DOCKHCENTER)

GUISetState() ; показывает созданное окно

; Запускается цикл опроса GUI до тех пор пока окно не будет закрыто
While 1
$msg = GUIGetMsg()

If $msg = $GUI_EVENT_CLOSE Then ExitLoop
WEnd
EndFunc