Функция GUICtrlCreateInput

GUICtrlCreateInput

Создаёт Input (поле ввода) в GUI.

GUICtrlCreateInput ( "text", left, top [, width [, height [, style = -1 [, exStyle = -1 ]]]] )

Параметры

text	Текст элемента
left	Координата левого края. Если -1 - тогда координата в соответствии с GUICoordMode.
top	Координата верхнего края. Если -1 - тогда координата в соответствии с GUICoordMode.
width	[необязательный] Ширина элемента (по умолчанию предыдущее значение).
height	[необязательный] Высота элемента (по умолчанию предыдущее значение).
style	[необязательный] Стиль элемента. Смотрите Стили элементов GUI в приложении. -1 - по умолчанию : $ES_LEFT, $ES_AUTOHSCROLL принудительный стиль : $WS_TABSTOP только, если не используется $ES_READONLY. $ES_MULTILINE всегда отключен.
exStyle	[необязательный] Расширенный стиль элемента. Смотрите таблицу расширенных стилей. -1 - по умолчанию : $WS_EX_CLIENTEDGE

Возвращаемое значение

Успех:	Возвращает идентификатор (controlID) нового элемента.
Ошибка:	Возвращает 0.

Примечания

Для получения параметров элемента смотрите GUICtrlRead.
Чтобы установить или изменить параметры элемента смотрите GUICtrlUpdate....

При использовании элемента input для ввода паролей (ввод скрытый звёздочками) используйте стиль $ES_PASSWORD.

Если вы хотите перетаскивать файлы на этот элемент просто добавьте расширенный стиль в функции GUICreate() $WS_EX_ACCEPTFILES и установите элементу состояние $GUI_DROPACCEPTED.
При одновременном перетаскивании нескольких файлов на элемент Input вы можете извлечь пути к файлам, разделенных символом "|" используя GUICtrlRead.

Чтобы использовать параметры, указанные выше, вы должны включить в ваш скрипт #include <EditConstants.au3>.

По умолчанию стиль изменения размеров $GUI_DOCKHEIGHT (не изменяется высота).

См. также

GUICoordMode (Опция), GUICtrlUpdate..., GUIGetMsg, GUICtrlRead, GUICtrlCreateUpdown, GUICtrlSetLimit

Пример

#include <WindowsConstants.au3>
#include <GUIConstantsEx.au3>

Local $hGui, $msg, $Input1, $Input2, $Input3, $Input4, $BtnOk, $sText

$hGui = GUICreate("GUI с поддержкой drag and drop", 380, 160, @DesktopWidth / 2 - 190, @DesktopHeight / 2 - 80, -1, $WS_EX_ACCEPTFILES)
$Input1 = GUICtrlCreateInput('', 10, 5, 360, 20) ; принимает перетаскиваемые в Input файлы (drag and drop)
GUICtrlSetState(-1, $GUI_DROPACCEPTED)
$Input2 = GUICtrlCreateInput('', 10, 35, 360, 20, -1, $WS_EX_STATICEDGE) ; Стиль трёх-мерный
$Input3 = GUICtrlCreateInput('', 10, 65, 360, 22, -1, $WS_EX_DLGMODALFRAME) ; выпуклый
$Input4 = GUICtrlCreateInput('', 10, 95, 360, 22, $WS_BORDER)
$BtnOk = GUICtrlCreateButton("OK", (380 - 70) / 2, 127, 70, 26)

GUISetState()

While 1
$msg = GUIGetMsg()
Switch $msg
Case $GUI_EVENT_CLOSE
ExitLoop
Case $BtnOk
$sText = ''
$sText &= 'Input1 = ' & GUICtrlRead($Input1) & @CRLF
$sText &= 'Input2 = ' & GUICtrlRead($Input2) & @CRLF
$sText &= 'Input3 = ' & GUICtrlRead($Input3) & @CRLF
$sText &= 'Input4 = ' & GUICtrlRead($Input4) & @CRLF
MsgBox(0, "Результат", $sText, 0, $hGui)
EndSwitch
WEnd