Функция GUICtrlCreateTab

GUICtrlCreateTab

Создаёт Tab (вкладки) в GUI.

GUICtrlCreateTab ( left, top [, width [, height [, style = -1 [, exStyle = -1 ]]]] )

Параметры

left	Координата левого края. Если -1 - тогда координата в соответствии с GUICoordMode.
top	Координата верхнего края. Если -1 - тогда координата в соответствии с GUICoordMode.
width	[необязательный] Ширина элемента (по умолчанию предыдущее значение).
height	[необязательный] Высота элемента (по умолчанию предыдущее значение).
style	[необязательный] Стиль элемента. Смотрите Стили элементов GUI в приложении. -1 - по умолчанию : отсутствует. принудительный стиль : $WS_TABSTOP, $WS_CLIPSIBLINGS
exStyle	[необязательный] Расширенный стиль элемента. Смотрите таблицу расширенных стилей.

Возвращаемое значение

Успех:	Возвращает идентификатор (controlID) нового элемента.
Ошибка:	Возвращает 0.

Примечания

Этот элемент является обычным элементом, в котором создаются элементы tabitem (вкладки) и после на вкладках создаются другие элементы управления GUICtrlCreate... controls.

Чтобы установить или изменить параметры элемента смотрите GUICtrlUpdate....

Чтобы объединить стили со стилем по умолчанию используйте BitOR($GUI_SS_DEFAULT_TAB, новый стиль,...).

Чтобы использовать параметры, указанные выше, вы должны включить в ваш скрипт #include <TabConstants.au3>.

По умолчанию стиль изменения размеров $GUI_DOCKSIZE (не изменяется размер).

Только один элемент Tab может быть создан в окне. Но скрипт может создать несколько окон имеющих tab.

См. также

GUICtrlCreateTabItem, GUICoordMode (Опция), GUICtrlCreate..., GUICtrlUpdate..., GUIGetMsg

Пример

#include <GUIConstantsEx.au3>
#include <TabConstants.au3>

Local $tab, $iCombo, $msg, $Gui

$Gui = GUICreate("Вкладки (Tab) в GUI") ; Создаёт окно в центре экрана

GUISetBkColor(0xB4E1D3)
GUISetFont(9, 300)

$tab = GUICtrlCreateTab(10, 10, 380, 200)

GUICtrlCreateTabItem("Путь")
GUICtrlSetImage(-1, "shell32.dll", -222, 0) ; иконка вкладки
GUICtrlCreateLabel("Путь", 40, 43, 270, 17)
GUICtrlCreateButton("OK", 314, 60, 46, 25)
GUICtrlCreateInput("C:\WINDOWS\system32", 40, 60, 275, 25)

GUICtrlCreateTabItem("Выбор стиля")
GUICtrlSetState(-1, $GUI_SHOW) ; будет отображаться выбранной
GUICtrlCreateLabel("Выбери стиль", 20, 54, 250, 17)
$iCombo = GUICtrlCreateCombo("", 20, 70, 310, 120)
GUICtrlSetData(-1, "$GUI_SS_DEFAULT_TAB|$TCS_FIXEDWIDTH|$TCS_FIXEDWIDTH+$TCS_FORCEICONLEFT|$TCS_FIXEDWIDTH+$TCS_FORCELABELLEFT|$TCS_BOTTOM", "$GUI_SS_DEFAULT_TAB") ; по умолчанию стандартный стиль

GUICtrlCreateTabItem("?")
GUICtrlCreateLabel("Описание", 20, 40, 120, 17)
GUICtrlCreateButton("OK", 300, 150, 70, 30)

GUICtrlCreateTabItem("") ; определяет конец вкладок

GUICtrlCreateLabel('Можно применять иконки, стили оформления' & @CRLF & '$TCS_MULTILINE - вкладки в несколько рядов (вместо горизонтальной прокрутки)' & @CRLF & '$TCS_BUTTONS - вкладки как кнопки' & @CRLF & '$TCS_FLATBUTTONS+$TCS_BUTTONS - утопленные вкладки', 20, 230, 370, 100)

GUISetState()

; Запускается цикл опроса GUI до тех пор пока окно не будет закрыто
While 1
$msg = GUIGetMsg()
Switch $msg
Case $GUI_EVENT_CLOSE
ExitLoop
Case $tab
; отображает кликнутую вкладку
WinSetTitle($Gui, "", "Вкладки (Tab) в GUI, текущая " & GUICtrlRead($tab))
Case $iCombo
GUICtrlSetStyle($tab, BitOR($GUI_SS_DEFAULT_TAB, Execute(GUICtrlRead($iCombo))))
EndSwitch
WEnd