Функция _GUICtrlTreeView_GetNextSibling

 ↑  ←  Описание функции

_GUICtrlTreeView_GetNextSibling

Возвращает следующий пункт на том же уровне, что и указанный пункт

#include <GuiTreeView.au3>
_GUICtrlTreeView_GetNextSibling($hWnd, $hItem)

Параметры

$hWnd Дескриптор или идентификатор элемента
$hItem Дескриптор пункта

Возвращаемое значение

Успех:Возвращает дескриптор следующего соседнего пункта
Ошибка:Возвращает 0

Примечания

Возвращает следующий пункт в пределах одного уровня вложения. Если указанный пункт является последним в пределах уровня вложения, то функция возвращает 0.

См. также

_GUICtrlTreeView_GetNext, _GUICtrlTreeView_GetPrevSibling

Пример

#include <GUIConstantsEx.au3>
#include <GuiTreeView.au3>
#include <WindowsConstants.au3>

$Debug_TV = False ; Проверяет ClassName передаваемый в функции. Установите True и используйте дескриптор от другого элемента, чтобы увидеть как это работает

_Main()

Func _Main()

    Local $hItem[10], $hRandItem, $hTreeView
    Local $iStyle = BitOR($TVS_EDITLABELS, $TVS_HASBUTTONS, $TVS_HASLINES, $TVS_LINESATROOT, $TVS_DISABLEDRAGDROP, $TVS_SHOWSELALWAYS, $TVS_CHECKBOXES)

    GUICreate("Следующий одноуровневый пункт", 400, 300)

    $hTreeView = GUICtrlCreateTreeView(2, 2, 396, 268, $iStyle, $WS_EX_CLIENTEDGE)
    GUISetState()

    _GUICtrlTreeView_BeginUpdate($hTreeView)
    For $x = 0 To 3
        $hItem[$x] = GUICtrlCreateTreeViewItem(StringFormat("[%02d] Пункт", $x), $hTreeView)
        For $y = 1 To Random(2, 10, 1)
            GUICtrlCreateTreeViewItem(StringFormat("[%02d] Дочерний", $y), $hItem[$x])
        Next
    Next
    $hItem[4] = GUICtrlCreateTreeViewItem(StringFormat("[%02d] Пункт", 4), $hTreeView)
    For $x = 5 To 9
        $hItem[$x] = GUICtrlCreateTreeViewItem(StringFormat("[%02d] Пункт", $x), $hTreeView)
        For $y = 1 To Random(2, 10, 1)
            GUICtrlCreateTreeViewItem(StringFormat("[%02d] Дочерний", $y), $hItem[$x])
        Next
    Next
    _GUICtrlTreeView_EndUpdate($hTreeView)

    $hRandItem = Random(0, 8, 1)
    _GUICtrlTreeView_SelectItem($hTreeView, $hItem[$hRandItem]) ; выделяет пункт
    MsgBox(4160, "Информация", StringFormat("Индекс %d, дескриптор следующего: %s", $hRandItem, _GUICtrlTreeView_GetNextSibling($hTreeView, $hItem[$hRandItem])))
    _GUICtrlTreeView_SelectItem($hTreeView, _GUICtrlTreeView_GetNextSibling($hTreeView, $hItem[$hRandItem])) ; выделяет следующий

    ; Цикл выполняется, пока окно не будет закрыто
    Do
    Until GUIGetMsg() = $GUI_EVENT_CLOSE
    GUIDelete()
EndFunc   ;==>_Main