Функция _GUICtrlTreeView_GetNext

 ↑  ←  Описание функции

_GUICtrlTreeView_GetNext

Возвращает следующий пункт после указанного пункта

#include <GuiTreeView.au3>
_GUICtrlTreeView_GetNext($hWnd, $hItem)

Параметры

$hWnd Дескриптор или идентификатор элемента
$hItem Дескриптор пункта

Возвращаемое значение

Успех:Возвращает дескриптор следующего пункта
Ошибка:Возвращает 0

Примечания

Если указанный пункт является последним, то функция возвращает 0, иначе возвращается следующий пункт включая невидимые и дочерние пункты. Чтобы получить следующий пункт на том же уровне, что и указанный используйте _GUICtrlTreeView_GetNextSibling. Чтобы получить следующий видимый пункт, используйте _GUICtrlTreeView_GetNextVisible.

См. также

_GUICtrlTreeView_GetNextVisible, _GUICtrlTreeView_GetNextSibling, _GUICtrlTreeView_GetPrev

Пример

#include <GUIConstantsEx.au3>
#include <GuiTreeView.au3>
#include <WindowsConstants.au3>

$Debug_TV = False ; Проверяет ClassName передаваемый в функции. Установите True и используйте дескриптор от другого элемента, чтобы увидеть как это работает

_Main()

Func _Main()

    Local $hItem[10], $hTreeView
    Local $iStyle = BitOR($TVS_EDITLABELS, $TVS_HASBUTTONS, $TVS_HASLINES, $TVS_LINESATROOT, $TVS_DISABLEDRAGDROP, $TVS_SHOWSELALWAYS, $TVS_CHECKBOXES)

    GUICreate("Получить следующий пункт", 400, 300)

    $hTreeView = GUICtrlCreateTreeView(2, 2, 396, 268, $iStyle, $WS_EX_CLIENTEDGE)
    GUISetState()

    _GUICtrlTreeView_BeginUpdate($hTreeView)
    For $x = 0 To 3
        $hItem[$x] = GUICtrlCreateTreeViewItem(StringFormat("[%02d] Пункт", $x + 1), $hTreeView)
        For $y = 1 To Random(2, 10, 1)
            GUICtrlCreateTreeViewItem(StringFormat("[%02d] Дочерний", $y), $hItem[$x])
        Next
    Next
    $hItem[4] = GUICtrlCreateTreeViewItem(StringFormat("[%02d] Пункт", 5), $hTreeView)
    For $x = 5 To 9
        $hItem[$x] = GUICtrlCreateTreeViewItem(StringFormat("[%02d] Пункт", $x + 1), $hTreeView)
        For $y = 1 To Random(2, 10, 1)
            GUICtrlCreateTreeViewItem(StringFormat("[%02d] Дочерний", $y), $hItem[$x])
        Next
    Next
    _GUICtrlTreeView_EndUpdate($hTreeView)

    MsgBox(4160, "Информация", "Индекс 2, Дескриптор следующего: " & _GUICtrlTreeView_GetNext($hTreeView, $hItem[2]))
    _GUICtrlTreeView_SelectItem($hTreeView, _GUICtrlTreeView_GetNext($hTreeView, $hItem[2]))

    MsgBox(4160, "Информация", "Индекс 4, Дескриптор следующего: " & _GUICtrlTreeView_GetNext($hTreeView, $hItem[4]))
    _GUICtrlTreeView_SelectItem($hTreeView, _GUICtrlTreeView_GetNext($hTreeView, $hItem[4]))

    ; Цикл выполняется, пока окно не будет закрыто
    Do
    Until GUIGetMsg() = $GUI_EVENT_CLOSE
    GUIDelete()
EndFunc   ;==>_Main