Функция _GUICtrlTreeView_GetPrevSibling

 ↑  ←  Описание функции

_GUICtrlTreeView_GetPrevSibling

Возвращает дескриптор предыдущего пункта, перед указанным пунктом на том же уровне

#include <GuiTreeView.au3>
_GUICtrlTreeView_GetPrevSibling($hWnd, $hItem)

Параметры

$hWnd Дескриптор или идентификатор элемента
$hItem Дескриптор пункта

Возвращаемое значение

Успех:Возвращает дескриптор предыдущего соседнего пункта
Ошибка:Возвращает 0

Примечания

Возвращает предыдущий пункт в пределах одного уровня вложения. Если указанный пункт является первым в пределах уровня вложения, то функция возвращает 0.

См. также

_GUICtrlTreeView_GetNextSibling

Пример

#include <GUIConstantsEx.au3>
#include <GuiTreeView.au3>
#include <WindowsConstants.au3>

$Debug_TV = False ; Проверяет ClassName передаваемый в функции. Установите True и используйте дескриптор от другого элемента, чтобы увидеть как это работает

_Main()

Func _Main()

    Local $hItem[10], $hRandItem, $hTreeView, $fBoolean = True
    Local $iStyle = BitOR($TVS_EDITLABELS, $TVS_HASBUTTONS, $TVS_HASLINES, $TVS_LINESATROOT, $TVS_DISABLEDRAGDROP, $TVS_SHOWSELALWAYS, $TVS_CHECKBOXES)

    GUICreate("Предыдущий одноуровневый пункт", 400, 300)

    $hTreeView = GUICtrlCreateTreeView(2, 2, 396, 268, $iStyle, $WS_EX_CLIENTEDGE)
    GUISetState()

    _GUICtrlTreeView_BeginUpdate($hTreeView)
    For $x = 0 To 9
        $hItem[$x] = GUICtrlCreateTreeViewItem(StringFormat("[%02d] Пункт", $x), $hTreeView)
        $fBoolean = Not $fBoolean
        If $fBoolean Then
            For $y = 1 To Random(2, 10, 1)
                GUICtrlCreateTreeViewItem(StringFormat("[%02d] Дочерний", $y), $hItem[$x])
            Next
        EndIf
    Next
    _GUICtrlTreeView_EndUpdate($hTreeView)

    $hRandItem = Random(0, 8, 1)
    _GUICtrlTreeView_SelectItem($hTreeView, $hItem[$hRandItem]) ; выделяет пункт
    MsgBox(4160, "Информация", StringFormat("Индекс %d, дескриптор предыдущего: %s", $hRandItem, _GUICtrlTreeView_GetPrevSibling($hTreeView, $hItem[$hRandItem])))
    _GUICtrlTreeView_SelectItem($hTreeView, _GUICtrlTreeView_GetPrevSibling($hTreeView, $hItem[$hRandItem])) ; выделяет предыдущий

    ; Цикл выполняется, пока окно не будет закрыто
    Do
    Until GUIGetMsg() = $GUI_EVENT_CLOSE
    GUIDelete()
EndFunc   ;==>_Main