Функция _GUICtrlSlider_SetTipSide

 ↑  ←  Описание функции

_GUICtrlSlider_SetTipSide

Устанавливает позицию подсказки

#include <GuiSlider.au3>
_GUICtrlSlider_SetTipSide($hWnd, $fLocation)

Параметры

$hWnd Дескриптор или идентификатор элемента
$fLocation Позиция, в которой отображается подсказка. Это может быть одно из следующих значений:
    $TBTS_TOP - Над ползунком. Этот флаг используется с горизонтальным Slider.
    $TBTS_LEFT - Слева от ползунка. Этот флаг используется с вертикальным Slider.
    $TBTS_BOTTOM - Под ползунком. Этот флаг используется с горизонтальными Slider.
    $TBTS_RIGHT - Справа от ползунка. Этот флаг используется с вертикальным Slider.

Возвращаемое значение

Успех: Возвращает предыдущую позицию подсказки.
    Это значение принадлежит одному из возможных значений $fLocation

Примечания

Use the $TBS_TOOLTIPS style display ToolTips

Пример

#include <GUIConstantsEx.au3>
#include <GuiSlider.au3>

$Debug_S = False ; Проверяет ClassName передаваемый в функции. Установите True и используйте дескриптор от другого элемента, чтобы увидеть как это работает

_Main()

Func _Main()
    Local $rdoBottom, $rdoLeft, $rdoRight, $rdoTop, $hSlider, $hSlider2

    ; Создаёт GUI
    GUICreate("Позиция подсказки", 400, 296)
    $hSlider = GUICtrlCreateSlider(2, 2, 325, 35, BitOR($TBS_TOOLTIPS, $TBS_AUTOTICKS))
    $hSlider2 = GUICtrlCreateSlider(355, 2, 35, 282, BitOR($TBS_TOOLTIPS, $TBS_AUTOTICKS, $TBS_VERT))
    GUISetState()

    GUICtrlCreateGroup("Для горизонтального", 42, 60, 120, 70)
    $rdoTop = GUICtrlCreateRadio("Сверху", 75, 80, 70, 20)
    $rdoBottom = GUICtrlCreateRadio("Снизу", 75, 100, 70, 20)
    GUICtrlCreateGroup("", -99, -99, 1, 1)
    GUICtrlSetState($rdoTop, $GUI_CHECKED)

    GUICtrlCreateGroup("Для вертикального", 170, 60, 120, 70)
    $rdoLeft = GUICtrlCreateRadio("Слева", 202, 80, 70, 20)
    $rdoRight = GUICtrlCreateRadio("Справа", 202, 100, 70, 20)
    GUICtrlCreateGroup("", -99, -99, 1, 1)
    GUICtrlSetState($rdoLeft, $GUI_CHECKED)

    ; Цикл выполняется, пока окно не будет закрыто
    While 1
        Switch GUIGetMsg()
            Case $GUI_EVENT_CLOSE
                ExitLoop
            Case $rdoBottom
                _GUICtrlSlider_SetTipSide($hSlider, $TBTS_BOTTOM)
            Case $rdoLeft
                _GUICtrlSlider_SetTipSide($hSlider2, $TBTS_LEFT)
            Case $rdoRight
                _GUICtrlSlider_SetTipSide($hSlider2, $TBTS_RIGHT)
            Case $rdoTop
                _GUICtrlSlider_SetTipSide($hSlider, $TBTS_TOP)
        EndSwitch
    WEnd
    GUIDelete()
EndFunc   ;==>_Main