Функция GUICtrlCreateGroup

GUICtrlCreateGroup

Создаёт Group (группа) в GUI.

GUICtrlCreateGroup ( "text", left, top [, width [, height [, style = -1 [, exStyle = -1 ]]]] )

Параметры

text	Текст элемента
left	Координата левого края. Если -1 - тогда координата в соответствии с GUICoordMode.
top	Координата верхнего края. Если -1 - тогда координата в соответствии с GUICoordMode.
width	[необязательный] Ширина элемента (по умолчанию предыдущее значение).
height	[необязательный] Высота элемента (по умолчанию предыдущее значение).
style	[необязательный] Стиль элемента. Смотрите Стили элементов GUI в приложении. -1 - по умолчанию : none. принудительный стиль : $WS_GROUP, $BS_GROUPBOX.
exStyle	[необязательный] Расширенный стиль элемента. Смотрите таблицу расширенных стилей.

Возвращаемое значение

Успех:	Возвращает идентификатор (controlID) нового элемента.
Ошибка:	Возвращает 0.

Примечания

Элемент group (группа) - тонкая линия, которую вы видите вокруг других созданных элементов (как правило, только для Radio-кнопки) это визуально группирует их вместе. Только одна Radio-кнопка в группе может быть выбрана.
Если вы хотите иметь несколько групп без видимой линии, то вы должны использовать GUIStartGroup() для вашей группы Radio-кнопок.

Чтобы использовать параметры, указанные выше, вы должны включить в ваш скрипт #include <ButtonConstants.au3>.

По умолчанию стиль изменения размеров $GUI_DOCKAUTO (размер и позиция изменяются пропорционально).

См. также

GUICoordMode (Опция), GUIStartGroup

Пример

#include <GUIConstantsEx.au3>

Local $iRadio_1, $iRadio_2, $iRadio_3, $iRadio_4, $msg

GUICreate("Объединяет радиокнопки в группы") ; Создаёт окно в центре экрана

GUICtrlCreateGroup("Группа 1", 90, 60, 130, 90)
$iRadio_1 = GUICtrlCreateRadio("Радиокнопка 1", 110, 90, 100, 20)
$iRadio_2 = GUICtrlCreateRadio("Радиокнопка 2", 110, 110, 100, 20)
GUICtrlCreateGroup("", -99, -99, 1, 1) ; закрывает группу

GUICtrlCreateGroup("Группа 2", 90, 160, 130, 90)
$iRadio_3 = GUICtrlCreateRadio("Радиокнопка 3", 110, 190, 100, 20)
$iRadio_4 = GUICtrlCreateRadio("Радиокнопка 4", 110, 210, 100, 20)
GUICtrlCreateGroup("", -99, -99, 1, 1) ; закрывает группу

GUISetState() ; показывает созданное окно

; Запускается цикл опроса GUI до тех пор пока окно не будет закрыто
While 1
$msg = GUIGetMsg()

If $msg = $GUI_EVENT_CLOSE Then ExitLoop
WEnd