Функция _GUICtrlRichEdit_StreamToVar

 ↑  ←  Описание функции

_GUICtrlRichEdit_StreamToVar

Записывает содержание элемента Rich Edit в переменную

#include <GuiRichEdit.au3>
_GUICtrlRichEdit_StreamToVar($hWnd [, $fRtf = True [, $fIncludeCOM=True [, $iOpts=0 [, $iCodePage = 0]]]])

Параметры

$hWnd Дескриптор элемента
$fRtf [необязательный] True - записывать Rich Text Format (RTF) (по умолчанию)
    False - записывать только текст
$fIncludeCOM [необязательный] True (по умолчанию):
    Если записывается RTF, то включает в себя любые COM-объекты (space consuming)
    Если записывается только текст, то записывается текстовое представление COM-объектов
    False: Записывает пробелы вместо COM-объектов
$iOpts [необязательный] additional options:
    $SFF_PLAINTRTF - записывать только rich text keywords общий для всех языков
    $SF_UNICODE - записывать Unicode
$iCodePage [необязательный] Создать UTF-8 и текст использующий эту кодовую страницу
    По умолчанию: не использовать

Возвращаемое значение

Успех:Возвращает RTF или текст
Ошибка:Возвращает "" (пустую строку) и устанавливает @error
@error:101 - $HWnd не является дескриптором
1041 - $SFF_PLAINRTF недопустим для текстового файла
1042 - $opts: недопустимые опции
1043 - $SF_UNICODE допустимо только для текстовых файлов
700 - внутренняя ошибка

Примечания

Если текст выделен, то заменяется выделенное, иначе заменяется весь текст в элементе Rich Edit

Если расширение файла в $sFileSpec является .rtf, то записывается RTF, иначе текст

Используйте функцию _GUICtrlRichEdit_IsModified(), чтобы определить, изменился ли текст

См. также

_GUICtrlRichEdit_SetLimitOnText, _GUICtrlRichEdit_StreamFromVar, _GUICtrlRichEdit_StreamToFile

См. также

Искать EM_STREAMIN в библиотеке MSDN

Пример

#include <GuiRichEdit.au3>
#include <GUIConstantsEx.au3>
#include <WindowsConstants.au3>

Main()

Func Main()
    Local $hGui, $btnNext, $iStep = 0, $lblMsg, $hRichEdit, $s
    $hGui = GUICreate(StringTrimRight(@ScriptName, 4), 420, 350, -1, -1)
    $hRichEdit = _GUICtrlRichEdit_Create($hGui, 'Это тест.', 10, 10, 400, 220, _
            BitOR($ES_MULTILINE, $WS_VSCROLL, $ES_AUTOVSCROLL))
    $lblMsg = GUICtrlCreateLabel("", 10, 235, 400, 75)
    $btnNext = GUICtrlCreateButton("Далее", 270, 310, 60, 30)
    GUISetState()

    While 1
        Switch GUIGetMsg()
            Case $GUI_EVENT_CLOSE
                _GUICtrlRichEdit_Destroy($hRichEdit)
                GUIDelete()
                Exit
            Case $btnNext
                $iStep += 1
                Switch $iStep
                    Case 1
                        _GUICtrlRichEdit_SetSel($hRichEdit, 0, -1)
                        $s = _GUICtrlRichEdit_StreamToVar($hRichEdit)
                        GUICtrlSetData($lblMsg, "Чтение кода RTF в переменную:" & @CR & $s)
                        ; ClipPut($s)
                    Case 2
                        _GUICtrlRichEdit_SetText($hRichEdit, "")
                        $s = StringReplace($s, 'fcharset204 MS Shell Dlg;', 'fcharset204 Times New Roman;') ; Изменение шрифта с помощью тегов
                        $s = StringRegExpReplace($s, '\\fs\d{1,2}', '\\fs32') ; Изменение размера шрифта с помощью тегов
                        _GUICtrlRichEdit_StreamFromVar($hRichEdit, $s)
                        GUICtrlSetData($lblMsg, "Вставка кода RTF из переменной")
                    Case 3
                        _GUICtrlRichEdit_SetSel($hRichEdit, 2, 6)
                        _GUICtrlRichEdit_StreamFromVar($hRichEdit, $s)
                        GUICtrlSetData($lblMsg, "Замена выделенного: умышленная путаница!")
                        GUICtrlSetState($btnNext, $GUI_DISABLE)
                EndSwitch
        EndSwitch
    WEnd
EndFunc   ;==>Main