Функция _GUICtrlRichEdit_SetParaNumbering

 ↑  ←  Описание функции

_GUICtrlRichEdit_SetParaNumbering

Sets numbering of paragraph(s) in the current selection or, if no selection, of paragraph(s) inserted at the insertion point

#include <GuiRichEdit.au3>
_GUICtrlRichEdit_SetParaNumbering($hWnd, $sStyle [, $iTextToNbrSpace = Default [, $fForceRoman=False]])

Параметры

$hWnd Дескриптор элемента
$sStyle a string specifying style and starting "number": e.g. "." (bullet), "1)","(b)", "C.", "iv", "V)"
    This is the "numbering" that will display for the first paragraph.
    Trailing spaces indicate the minimum spaces between the number and the paragraph unless iTextToNbrSpace is entered
    Special cases:
    "=" - This paragraph is an unnumbered paragraph within the preceding list element
    "" - removed the numbering from the selected paragraph(s)
$iTextToNbrSpace [необязательный] space between number/bullet and paragraph (in space units)
    Default: number of trailing spaces times point size
$fForceRoman [необязательный] False - i, v, x ... in $sStyle is letter i, v, x ... {Default)

Возвращаемое значение

Успех:Возвращает True
Ошибка:Возвращает False и устанавливает @error
@error:101 - $hWnd is not a handle
102 - $sStyle is invalid
103 - $iTextToNbrSpace is not a postive number
104 - $fForceRoman must be True or False

Примечания

To set "space units", call _GUICtrlRichEdit_SetSpaceUnit. Initially inches

См. также

_GUICtrlRichEdit_GetParaNumbering, _GUICtrlRichEdit_SetSpaceUnit

См. также

Искать EM_SETPARAFORMAT в библиотеке MSDN

Пример

#include <GuiRichEdit.au3>
#include <GUIConstantsEx.au3>
#include <WindowsConstants.au3>

Global $lblMsg, $hRichEdit

Main()

Func Main()
    Local $hGui, $btnNext, $iStep = 0
    $hGui = GUICreate(StringTrimRight(@ScriptName, 4), 420, 350, -1, -1)
    $hRichEdit = _GUICtrlRichEdit_Create($hGui, 'Это тест.', 10, 10, 400, 220, _
            BitOR($ES_MULTILINE, $WS_VSCROLL, $ES_AUTOVSCROLL))
    $lblMsg = GUICtrlCreateLabel("", 10, 235, 300, 60)
    $btnNext = GUICtrlCreateButton("Далее", 270, 310, 60, 30)
    GUISetState()

    _GUICtrlRichEdit_SetText($hRichEdit, "First paragraph")
    _GUICtrlRichEdit_SetSel($hRichEdit, 0, 1)
    Report("Para with default indent settings")

    While 1
        Switch GUIGetMsg()
            Case $GUI_EVENT_CLOSE
                _GUICtrlRichEdit_Destroy($hRichEdit)
                GUIDelete()
                Exit
            Case $btnNext
                $iStep += 1
                Switch $iStep
                    Case 1
                        _GUICtrlRichEdit_AppendText($hRichEdit, @CR & "Second paragraph")
                        _GUICtrlRichEdit_SetParaNumbering($hRichEdit, ".")
                        Report("Added second paragraph")
                    Case 2
                        _GUICtrlRichEdit_SetSel($hRichEdit, 0, 2)
                        Report("Style of first paragraph in the selection")
                    Case 3
                        _GUICtrlRichEdit_SetSel($hRichEdit, 10, 26)
                        _GUICtrlRichEdit_SetParaNumbering($hRichEdit, "v)  ", Default, True)
                        Report("Change settings of both paragraphs")
                    Case 4
                        _GUICtrlRichEdit_SetSel($hRichEdit, 10, 26)
                        _GUICtrlRichEdit_SetParaNumbering($hRichEdit, "2.  ", Default, True)
                        Report("Changed settings for both paragraphs")
                    Case 5
                        ; Весь RTF-код сохраняет в файл на Рабочем столе чтобы посмотреть в Word
                        _GUICtrlRichEdit_Deselect($hRichEdit)
                        _GUICtrlRichEdit_StreamToFile($hRichEdit, @DesktopDir & "\gcre.rtf")
                        GUICtrlSetState($btnNext, $GUI_DISABLE)
                EndSwitch
        EndSwitch
    WEnd
EndFunc   ;==>Main

Func Report($sMsg)
    $sMsg &=  @CR & @CR & "Get function returns " & @CR & _GUICtrlRichEdit_GetParaNumbering($hRichEdit)
    GUICtrlSetData($lblMsg, $sMsg)
    ControlFocus($hRichEdit, "", "")
EndFunc   ;==>Report