_GUICtrlRichEdit_GetCharBkColor
Возвращает цвет фона выделенного текста или, если не выделено, то символа справа от курсора
#include <GuiRichEdit.au3>
_GUICtrlRichEdit_GetCharBkColor($hWnd)
Параметры
| $hWnd | Дескриптор элемента |
Возвращаемое значение
| Успех: | Возвращает значение COLORREF, @extended равен 1 если цвет is the same throught the selection |
| Ошибка: | устанавливает @error |
| @error: | 101 - $HWnd не является дескриптором |
Примечания
Если вам нужно создать массив значений цвета, то используйте _ColorGetCOLORREF(), а не _ColorGetRGB().См. также
_GUICtrlRichEdit_SetCharBkColorСм. также
Искать EM_GETCHARFORMAT в библиотеке MSDNПример
#include <GuiRichEdit.au3>
#include <GUIConstantsEx.au3>
#include <WindowsConstants.au3>
#include <Color.au3>
Global $lblMsg, $hRichEdit
Main()
Func Main()
Local $hGui, $btnNext, $iStep = 0
$hGui = GUICreate(StringTrimRight(@ScriptName, 4), 420, 350, -1, -1)
$hRichEdit = _GUICtrlRichEdit_Create($hGui, 'Это тест.', 10, 10, 400, 220, _
BitOR($ES_MULTILINE, $WS_VSCROLL, $ES_AUTOVSCROLL))
$lblMsg = GUICtrlCreateLabel("", 10, 235, 300, 60)
$btnNext = GUICtrlCreateButton("Далее", 270, 310, 60, 30)
GUISetState()
While 1
Switch GUIGetMsg()
Case $GUI_EVENT_CLOSE
_GUICtrlRichEdit_Destroy($hRichEdit)
GUIDelete()
Exit
Case $btnNext
$iStep += 1
Switch $iStep
Case 1
Report("1. Текущий цвет")
Case 2
_GUICtrlRichEdit_SetCharBkColor($hRichEdit, Dec('00FF00'))
Report("2. Изменённый цвет")
Case 3
_GUICtrlRichEdit_SetSel($hRichEdit, 1, 5)
_GUICtrlRichEdit_SetCharBkColor($hRichEdit, Dec('8888FF'))
Report("3. Цвет фона некоторых символов изменился")
Case 4
; Весь RTF-код сохраняет в файл на Рабочем столе чтобы посмотреть в Word
_GUICtrlRichEdit_StreamToFile($hRichEdit, @DesktopDir & "\gcre.rtf")
GUICtrlSetState($btnNext, $GUI_DISABLE)
GUICtrlSetData($lblMsg, "4. Сохранено в файл gcre.rtf на рабочий стол")
EndSwitch
EndSwitch
WEnd
EndFunc ;==>Main
Func Report($sMsg)
Local $iColor = _GUICtrlRichEdit_GetCharBkColor($hRichEdit)
Local $aRet = _ColorGetRGB($iColor)
$sMsg &= @CR & @CR & $aRet[0] & ";" & $aRet[1] & ";" & $aRet[2] & " BkColor=0x" & Hex($iColor)
GUICtrlSetData($lblMsg, $sMsg)
EndFunc ;==>Report