Описание функции

_GUICtrlRebar_GetBKColor

Возвращает цвет фона по умолчанию элемента Rebar

#include <GuiReBar.au3>
_GUICtrlRebar_GetBKColor($hWnd)

Параметры

Возвращаемое значение

См. также

Пример

#include <Constants.au3>
#include <GUIConstantsEx.au3>
#include <GuiReBar.au3>
#include <GuiToolbar.au3>
#include <WindowsConstants.au3>

$Debug_RB = False

Global $iMemo

_Main()

Func _Main()
    Local $hGUI, $hReBar, $hToolbar, $iInput
    Local Enum $idNew = 1000, $idOpen, $idSave, $idHelp

    $hGUI = GUICreate(StringTrimRight(@ScriptName, 4), 400, 396, -1, -1, BitOR($WS_MINIMIZEBOX, $WS_CAPTION, $WS_POPUP, $WS_SYSMENU, $WS_MAXIMIZEBOX))

    ; Создаёт элемент ReBar
    $hReBar = _GUICtrlRebar_Create($hGUI, BitOR($CCS_TOP, $WS_BORDER, $RBS_VARHEIGHT, $RBS_AUTOSIZE, $RBS_BANDBORDERS))

    $iMemo = GUICtrlCreateEdit("", 2, 100, 396, 250, $WS_VSCROLL)
    GUICtrlSetFont($iMemo, 10, 400, 0, "Courier New")


    ; Создаёт элемент ToolBar, чтобы вставить его в ReBar
    $hToolbar = _GUICtrlToolBar_Create($hGUI, BitOR($TBSTYLE_FLAT, $CCS_NORESIZE, $CCS_NOPARENTALIGN))

    ; Добавляет стандартный системный bitmaps
    Switch _GUICtrlToolbar_GetBitmapFlags($hToolbar)
        Case 0
            _GUICtrlToolbar_AddBitmap($hToolbar, 1, -1, $IDB_STD_SMALL_COLOR)
        Case 2
            _GUICtrlToolbar_AddBitmap($hToolbar, 1, -1, $IDB_STD_LARGE_COLOR)
    EndSwitch

    ; Добавляет кнопки
    _GUICtrlToolbar_AddButton($hToolbar, $idNew, $STD_FILENEW)
    _GUICtrlToolbar_AddButton($hToolbar, $idOpen, $STD_FILEOPEN)
    _GUICtrlToolbar_AddButton($hToolbar, $idSave, $STD_FILESAVE)
    _GUICtrlToolbar_AddButtonSep($hToolbar)
    _GUICtrlToolbar_AddButton($hToolbar, $idHelp, $STD_HELP)

    ; Создаёт поле ввода, чтобы вставить его в ReBar
    $iInput = GUICtrlCreateInput("Поле ввода", 0, 0, 120, 20)

    ; Добавляет ленту содержащую элемент
    _GUICtrlRebar_AddBand($hReBar, GUICtrlGetHandle($iInput), 120, 200, "Заголовок:")

    ; Добавляет ленту, содержащую элемент, в начало ReBar
    _GUICtrlRebar_AddToolBarBand($hReBar, $hToolbar, "", 0)

    GUISetState(@SW_SHOW)

    _GUICtrlRebar_SetBandStyleBreak($hReBar, 1)

    MemoWrite("========== Цвет ReBar ==========")
    MemoWrite("Предыдущий цвет фона .: " & _GUICtrlRebar_SetBKColor($hReBar, 0x00008B))
    MemoWrite("Текущий цвет фона ....: 0x" & Hex(_GUICtrlRebar_GetBKColor($hReBar), 6))
    MemoWrite("Предыдущий цвет текста: " & _GUICtrlRebar_SetTextColor($hReBar, 0xFFFFFF))
    MemoWrite("Текущий цвет текста ..: 0x" & Hex(_GUICtrlRebar_GetTextColor($hReBar), 6))

    While 1
        Switch GUIGetMsg()
            Case $GUI_EVENT_CLOSE
                Exit
        EndSwitch
    WEnd
EndFunc   ;==>_Main

; Записывает строку в элемент для заметок
Func MemoWrite($sMessage = "")
    GUICtrlSetData($iMemo, $sMessage & @CRLF, 1)
EndFunc   ;==>MemoWrite