Функция _GUICtrlRebar_AddToolBarBand

         Описание функции

_GUICtrlRebar_AddToolBarBand

Добавляет новую ленту в Rebar

#include <GuiReBar.au3>
_GUICtrlRebar_AddToolBarBand($hwndRebar, $hwndToolbar [, $sText = "" [, $iIndex = -1 [, $fStyle = -1]]])

Параметры

$hwndRebar Дескриптор Rebar
$hwndToolbar Дескриптор добавляемого Toolbar
$sText [необязательный] Отображаемый текст на ленте
$iIndex [необязательный] Индекс-позиция, в которую лента будет вставлена, отсчёт от 0.
    Если этот параметр равен -1, то элемент будет добавлен в новую ленту в последнюю позицию
$fStyle [необязательный] Флаги, определяющие стиль ленты. Этот параметр может быть комбинацией следующих значений:
    $RBBS_BREAK - Помещает ленту на новую строку.
    $RBBS_CHILDEDGE - The band has an edge at the top and bottom of the child window.
    $RBBS_FIXEDBMP - Фоновый bitmap не перемещается при изменении размеров ленты.
    $RBBS_FIXEDSIZE - Размер ленты не может быть изменён. С этим стилем элемент захвата для изменения размера не отображается на ленте.
    $RBBS_GRIPPERALWAYS - Версия 4.71. Лента всегда отображает элемент захвата для изменения размера, даже если она единственная лента в Rebar.
    $RBBS_HIDDEN - Лента скрыта.
    $RBBS_NOGRIPPER - Версия 4.71. Лента никогда не отображает элемент захвата для изменения размера, даже если имеется более одной ленты в Rebar.
    $RBBS_USECHEVRON - Версия 5.80. Show a chevron button if the band is smaller than cxIdeal.
    $RBBS_VARIABLEHEIGHT - Версия 4.71. Размер ленты может изменится с помощью Rebar;
    cyIntegral and cyMaxChild affect how the rebar will resize the band.
    $RBBS_NOVERT - Don't show when vertical.
    $RBBS_USECHEVRON - Отображает drop-down кнопку.
    $RBBS_HIDETITLE - Скрывает заголовок ленты.
    $RBBS_TOPALIGN - Удерживает ленту на верхней строке.

Возвращаемое значение

Успех:Возвращает True
Ошибка:Возвращает False

См. также

_GUICtrlRebar_AddBand, _GUICtrlRebar_DeleteBand

Пример

#include <GUIConstantsEx.au3>
#include <GuiReBar.au3>
#include <GuiToolbar.au3>
#include <WindowsConstants.au3>
#include <Constants.au3>

$Debug_RB = False

_Main()

Func _Main()
    Local $hgui, $hToolbar, $hReBar, $hInput
    Local Enum $idNew = 1000, $idOpen, $idSave, $idHelp

    $hgui = GUICreate(StringTrimRight(@ScriptName, 4), 400, 396, -1, -1, BitOR($WS_MINIMIZEBOX, $WS_CAPTION, $WS_POPUP, $WS_SYSMENU, $WS_MAXIMIZEBOX))

    ; Создаёт элемент ReBar
    $hReBar = _GUICtrlRebar_Create($hgui, BitOR($CCS_TOP, $WS_BORDER, $RBS_VARHEIGHT, $RBS_AUTOSIZE, $RBS_BANDBORDERS))

    ; Создаёт элемент ToolBar, чтобы вставить его в ReBar
    $hToolbar = _GUICtrlToolBar_Create($hgui, BitOR($TBSTYLE_FLAT, $CCS_NORESIZE, $CCS_NOPARENTALIGN))

    ; Добавляет стандартный системный bitmaps
    Switch _GUICtrlToolbar_GetBitmapFlags($hToolbar)
        Case 0
            _GUICtrlToolbar_AddBitmap($hToolbar, 1, -1, $IDB_STD_SMALL_COLOR)
        Case 2
            _GUICtrlToolbar_AddBitmap($hToolbar, 1, -1, $IDB_STD_LARGE_COLOR)
    EndSwitch

    ; Добавляет кнопки
    _GUICtrlToolbar_AddButton($hToolbar, $idNew, $STD_FILENEW)
    _GUICtrlToolbar_AddButton($hToolbar, $idOpen, $STD_FILEOPEN)
    _GUICtrlToolbar_AddButton($hToolbar, $idSave, $STD_FILESAVE)
    _GUICtrlToolbar_AddButtonSep($hToolbar)
    _GUICtrlToolbar_AddButton($hToolbar, $idHelp, $STD_HELP)

    ; Создаёт поле ввода, чтобы вставить его в ReBar
    $hInput = GUICtrlCreateInput("Поле ввода", 0, 0, 120, 20)

    ; Добавляет ленту содержащую элемент
    _GUICtrlRebar_AddBand($hReBar, GUICtrlGetHandle($hInput), 120, 200, "Заголовок:")

    ; Добавляет ленту содержащую элемент в начало ReBar
    _GUICtrlRebar_AddToolBarBand($hReBar, $hToolbar, "", 0)

    GUISetState(@SW_SHOW)

    While 1
        Switch GUIGetMsg()
            Case $GUI_EVENT_CLOSE
                Exit
        EndSwitch
    WEnd
EndFunc   ;==>_Main