Функция _GUICtrlRebar

Функция _GUICtrlRebar_BeginDrag

_GUICtrlRebar_BeginDrag

Начинает операцию "перетащить и бросить"

#include <GuiReBar.au3>
_GUICtrlRebar_BeginDrag($hWnd, $iIndex [, $dwPos = -1])

Параметры

$hwndRebar	Дескриптор Rebar
$iIndex	Индекс ленты, который влияет на операцию "перетащить и бросить", отсчёт от 0
$dwPos	[необязательный] Двойное слово (DWORD), содержащее начальные координаты мыши. Горизонтальная координата содержится в младшем слове (LOWORD), а вертикальная координата содержится в старшем слове (HIWORD) If you pass (DWORD)-1, the rebar control will use the position of the mouse the last time the control's thread called GetMessage or PeekMessage

См. также

_GUICtrlRebar_DragMove, _GUICtrlRebar_EndDrag

Пример

#include <GUIConstantsEx.au3>
#include <GuiReBar.au3>
#include <GuiToolbar.au3>
#include <WindowsConstants.au3>
#include <Constants.au3>

$Debug_RB = False

_Main()

Func _Main()
Local $hgui, $hReBar, $hToolbar, $hInput, $btnBeginDrag
Local Enum $idNew = 1000, $idOpen, $idSave, $idHelp

$hgui = GUICreate(StringTrimRight(@ScriptName, 4), 400, 396, -1, -1, BitOR($WS_MINIMIZEBOX, $WS_CAPTION, $WS_POPUP, $WS_SYSMENU, $WS_MAXIMIZEBOX))

; Создаёт элемент ReBar
$hReBar = _GUICtrlRebar_Create($hgui, BitOR($CCS_TOP, $WS_BORDER, $RBS_VARHEIGHT, $RBS_AUTOSIZE, $RBS_BANDBORDERS))

; Создаёт элемент ToolBar, чтобы вставить его в ReBar
$hToolbar = _GUICtrlToolBar_Create($hgui, BitOR($TBSTYLE_FLAT, $CCS_NORESIZE, $CCS_NOPARENTALIGN))

; Добавляет стандартный системный bitmaps
Switch _GUICtrlToolbar_GetBitmapFlags($hToolbar)
Case 0
_GUICtrlToolbar_AddBitmap($hToolbar, 1, -1, $IDB_STD_SMALL_COLOR)
Case 2
_GUICtrlToolbar_AddBitmap($hToolbar, 1, -1, $IDB_STD_LARGE_COLOR)
EndSwitch

; Добавляет кнопки
_GUICtrlToolbar_AddButton($hToolbar, $idNew, $STD_FILENEW)
_GUICtrlToolbar_AddButton($hToolbar, $idOpen, $STD_FILEOPEN)
_GUICtrlToolbar_AddButton($hToolbar, $idSave, $STD_FILESAVE)
_GUICtrlToolbar_AddButtonSep($hToolbar)
_GUICtrlToolbar_AddButton($hToolbar, $idHelp, $STD_HELP)

; Создаёт поле ввода, чтобы вставить его в ReBar
$hInput = GUICtrlCreateInput("Поле ввода", 0, 0, 120, 20)

; Добавляет ленту содержащую элемент
_GUICtrlRebar_AddBand($hReBar, GUICtrlGetHandle($hInput), 120, 200, "Заголовок:")

; Добавляет ленту, содержащую элемент, в начало ReBar
_GUICtrlRebar_AddToolBarBand($hReBar, $hToolbar, "", 0)

$btnBeginDrag = GUICtrlCreateButton("Перетащить", 150, 330, 100, 25)
GUISetState(@SW_SHOW)

While 1
Switch GUIGetMsg()
Case $GUI_EVENT_CLOSE
Exit
Case $btnBeginDrag
_GUICtrlRebar_BeginDrag($hReBar, 0)
_GUICtrlRebar_DragMove($hReBar)
_GUICtrlRebar_EndDrag($hReBar)
EndSwitch
WEnd
EndFunc ;==>_Main