Функция _GUICtrlListView_EnsureVisible

         Описание функции

_GUICtrlListView_EnsureVisible

Гарантирует, чтобы пункт был полностью или частично видим

#include <GuiListView.au3>
_GUICtrlListView_EnsureVisible($hWnd, $iIndex [, $fPartialOK = False])

Параметры

$hWnd Дескриптор или идентификатор элемента
$iIndex Индекс пункта
$fPartialOK [необязательный] Значение, указывающее, что пункт должен быть полностью видим

Возвращаемое значение

Успех:Возвращает True
Ошибка:Возвращает False

Примечания

Если параметр $fPartialOK равен TRUE и пункт, по крайней мере, частично видим, то прокрутка не выполняется.

Пример

#include <GUIConstantsEx.au3>
#include <GuiListView.au3>

$Debug_LV = False ; Проверяет ClassName передаваемый в ListView функции. Установите True и используйте дескриптор от другого элемента, чтобы увидеть как это работает

_Main()

Func _Main()
    Local $hListView

    GUICreate("ListView - Гарантирует отображение", 400, 300)
    $hListView = GUICtrlCreateListView("Пункты", 2, 2, 394, 268)
    _GUICtrlListView_SetColumnWidth($hListView, 0, 100)
    _GUICtrlListView_SetExtendedListViewStyle($hListView, BitOR($LVS_EX_GRIDLINES, $LVS_EX_FULLROWSELECT))
    GUISetState()

    _GUICtrlListView_BeginUpdate($hListView)
    For $i = 1 To 100
        GUICtrlCreateListViewItem("Пункт " & $i, $hListView)
    Next
    _GUICtrlListView_EndUpdate($hListView)

    MsgBox(4160, "Информация", "Сделать видимым пункт 50")
    _GUICtrlListView_EnsureVisible($hListView, 49)

    ; Цикл выполняется, пока окно не будет закрыто
    Do
    Until GUIGetMsg() = $GUI_EVENT_CLOSE
    GUIDelete()
EndFunc   ;==>_Main