Описание функции

_GUICtrlListView_DeleteItemsSelected

Удаляет выделенные пункты

#include <GuiListView.au3>
_GUICtrlListView_DeleteItemsSelected($hWnd)

Параметры

Возвращаемое значение

См. также

Пример

#include <GUIConstantsEx.au3>
#include <GuiListView.au3>

$Debug_LV = False ; Проверяет ClassName передаваемый в ListView функции. Установите True и используйте дескриптор от другого элемента, чтобы увидеть как это работает

Example1()
Example2()
Example_UDF_Created()

Func Example1()
    Local $aItems[10][3], $hListView

    GUICreate("ListView Удаление выделенного пункта", 400, 300)
    $hListView = GUICtrlCreateListView("Кол1|Кол2|Кол3", 2, 2, 394, 268, BitOR($LVS_SHOWSELALWAYS, $LVS_NOSORTHEADER, $LVS_REPORT))
    _GUICtrlListView_SetExtendedListViewStyle($hListView, BitOR($LVS_EX_GRIDLINES, $LVS_EX_FULLROWSELECT))
    GUISetState()

    ; 3 колонки добавлены
    For $iI = 0 To 9
        GUICtrlCreateListViewItem("Пункт " & $iI & "|Пункт " & $iI & "-1|Пункт " & $iI & "-2", $hListView)
    Next

    _GUICtrlListView_SetItemSelected($hListView, Random(0, UBound($aItems) - 1, 1))

    MsgBox(4160, "Информация", "Удаление выделенного пункта")
    ; Пункты созданы с помощью встроенной в AutoIt функции, передаётся идентификатор
    MsgBox(4160, "Удалено?", _GUICtrlListView_DeleteItemsSelected($hListView))

    ; Цикл выполняется, пока окно не будет закрыто
    Do
    Until GUIGetMsg() = $GUI_EVENT_CLOSE
    GUIDelete()
EndFunc   ;==>Example1

Func Example2()
    Local $aItems[10][3], $hListView

    GUICreate("ListView Удаление выделенного пункта", 400, 300)
    $hListView = GUICtrlCreateListView("Кол1|Кол2|Кол3", 2, 2, 394, 268, BitOR($LVS_SHOWSELALWAYS, $LVS_NOSORTHEADER, $LVS_REPORT))
    _GUICtrlListView_SetExtendedListViewStyle($hListView, BitOR($LVS_EX_GRIDLINES, $LVS_EX_FULLROWSELECT))
    GUISetState()

    ; 3 колонки добавлены
    For $iI = 0 To UBound($aItems) - 1
        $aItems[$iI][0] = "Пункт " & $iI
        $aItems[$iI][1] = "Пункт " & $iI & "-1"
        $aItems[$iI][2] = "Пункт " & $iI & "-2"
    Next

    _GUICtrlListView_AddArray($hListView, $aItems)

    _GUICtrlListView_SetItemSelected($hListView, Random(0, UBound($aItems) - 1, 1))

    MsgBox(4160, "Информация", "Удаление выделенного пункта")
    ; Пункты созданы с помощью функций UDF, передаётся дескриптор
    MsgBox(4160, "Удалено?", _GUICtrlListView_DeleteItemsSelected(GUICtrlGetHandle($hListView)))

    ; Цикл выполняется, пока окно не будет закрыто
    Do
    Until GUIGetMsg() = $GUI_EVENT_CLOSE
    GUIDelete()
EndFunc   ;==>Example2

Func Example_UDF_Created()
    Local $GUI, $aItems[10][3], $hListView

    $GUI = GUICreate("(UDF) ListView Удаление выделенного пункта", 400, 300)
    $hListView = _GUICtrlListView_Create($GUI, "Кол1|Кол2|Кол3", 2, 2, 394, 268, BitOR($LVS_SHOWSELALWAYS, $LVS_NOSORTHEADER, $LVS_REPORT))
    _GUICtrlListView_SetExtendedListViewStyle($hListView, BitOR($LVS_EX_GRIDLINES, $LVS_EX_FULLROWSELECT))
    GUISetState()

    ; 3 колонки добавлены
    For $iI = 0 To UBound($aItems) - 1
        $aItems[$iI][0] = "Пункт " & $iI
        $aItems[$iI][1] = "Пункт " & $iI & "-1"
        $aItems[$iI][2] = "Пункт " & $iI & "-2"
    Next

    _GUICtrlListView_AddArray($hListView, $aItems)

    _GUICtrlListView_SetItemSelected($hListView, Random(0, UBound($aItems) - 1, 1))

    MsgBox(4160, "Информация", "Удаление выделенного пункта")
    ; Здесь уже передаётся дескриптор
    MsgBox(4160, "Удалено?", _GUICtrlListView_DeleteItemsSelected($hListView))

    ; Цикл выполняется, пока окно не будет закрыто
    Do
    Until GUIGetMsg() = $GUI_EVENT_CLOSE
    GUIDelete()
EndFunc   ;==>Example_UDF_Created