Функция _GUICtrlListView_SetItemSelected

         Описание функции

_GUICtrlListView_SetItemSelected

Делает пункт выделенным

#include <GuiListView.au3>
_GUICtrlListView_SetItemSelected($hWnd, $iIndex [, $fSelected = True [, $fFocused = False]])

Параметры

$hWnd Дескриптор или идентификатор элемента
$iIndex Индекс пункта, -1 делает выделенными все пункты при отсутствии стиля $LVS_SINGLESEL
$fSelected [необязательный] Если True, то пункт(ы) выделяются, иначе выделение убирается.
$fFocused [необязательный] Если True, то находится в фокусе, иначе нет.

Возвращаемое значение

Успех:Возвращает True
Ошибка:Возвращает False

Примечания

Если в ListView используется стиль $LVS_SINGLESEL, то установка параметра $iIndex равным -1 не сделает выделенными все пункты.

См. также

_GUICtrlListView_GetItemSelected

Пример

#include <GUIConstantsEx.au3>
#include <GuiListView.au3>

$Debug_LV = False ; Проверяет ClassName передаваемый в ListView функции. Установите True и используйте дескриптор от другого элемента, чтобы увидеть как это работает

_Main()

Func _Main()
    Local $hListView

    GUICreate("Выделяет пункт", 400, 300)
    $hListView = GUICtrlCreateListView("", 2, 2, 394, 268)
    GUISetState()

    ; Добавляет колонки
    _GUICtrlListView_AddColumn($hListView, "Пункты", 100)

    ; Добавляет пункты
    _GUICtrlListView_AddItem($hListView, "Пункт 1")
    _GUICtrlListView_AddItem($hListView, "Пункт 2")
    _GUICtrlListView_AddItem($hListView, "Пункт 3")

    ; Выделяет 2-ой пункт
    _GUICtrlListView_SetItemSelected($hListView, 1)
    MsgBox(4160, "Информация", "Выделен 2-ой пункт: " & _GUICtrlListView_GetItemSelected($hListView, 1))

    ; Цикл выполняется, пока окно не будет закрыто
    Do
    Until GUIGetMsg() = $GUI_EVENT_CLOSE
    GUIDelete()
EndFunc   ;==>_Main