Функция _GUICtrlListBox_FindInText

         Описание функции

_GUICtrlListBox_FindInText

Поиск пункта, содержащего указанный текст в любом месте текста пункта

#include <GuiListBox.au3>
_GUICtrlListBox_FindInText($hWnd, $sText [, $iStart = -1 [, $fWrapOK = True]])

Параметры

$hWnd Дескриптор или идентификатор элемента
$sText Текст поиска
$iStart [необязательный] Индекс пункта, от которого начинать поиск или -1, чтобы начать с самого начала. Отсчёт от 0. Сам указанный пункт исключается из поиска.
$fWrapOK [необязательный] Если True, то поиск будет продолжен с первого пункта, если ничего не найдено

Возвращаемое значение

Успех:Возвращает индекс пункта, отсчёт от 0
Ошибка:Возвращает -1

Примечания

Поиск без учёта регистра

См. также

_GUICtrlListBox_FindString, _GUICtrlListBox_SelectString

Пример

#include <GuiListBox.au3>
#include <GUIConstantsEx.au3>

$Debug_LB = False ; Проверяет ClassName передаваемый в ListBox функции. Установите True и используйте дескриптор от другого элемента, чтобы увидеть как это работает

_Main()

Func _Main()
    Local $iIndex, $hListBox

    ; Создаёт GUI
    GUICreate("Поиск текста в ListBox", 400, 296)
    $hListBox = GUICtrlCreateList("", 2, 2, 396, 296)

    GUISetState()

    ; Добавляет строки
    _GUICtrlListBox_BeginUpdate($hListBox)
    For $iI = 1 To 9
        _GUICtrlListBox_AddString($hListBox, StringFormat("%03d : Рандомная строка", Random(1, 100, 1)))
    Next
    _GUICtrlListBox_InsertString($hListBox, "тОчНыЙ тЕкСт", 3)
    _GUICtrlListBox_EndUpdate($hListBox)

    ; Поиск пункта
    $iIndex = _GUICtrlListBox_FindInText($hListBox, "текс")
    _GUICtrlListBox_SetCurSel($hListBox, $iIndex)

    ; Цикл выполняется, пока окно не будет закрыто
    Do
    Until GUIGetMsg() = $GUI_EVENT_CLOSE
    GUIDelete()
EndFunc   ;==>_Main