Функция _GUICtrlListBox_InsertString

         Описание функции

_GUICtrlListBox_InsertString

Вставляет пункт в указанную позицию

#include <GuiListBox.au3>
_GUICtrlListBox_InsertString($hWnd, $sText [, $iIndex = -1])

Параметры

$hWnd Дескриптор или идентификатор элемента
$sText Текст вставляемого пункта
$iIndex [необязательный] Индекс позиции вставляемого пункта, отсчёт от 0. Если этот параметр равен -1, то пункт добавляется в конец списка.

Возвращаемое значение

Успех:Возвращает индекс позиции пункта, отсчёт от 0
Ошибка:Возвращает -1

Примечания

Если $iIndex равен -1, то пункт добавляется в конец списка. В отличие от _GUICtrlListBox_AddString, эта функция не приводит к сортировке ListBox имеющий стиль $LBS_SORT.

См. также

_GUICtrlListBox_AddString, _GUICtrlListBox_DeleteString, _GUICtrlListBox_InitStorage

Пример

#include <GuiListBox.au3>
#include <GUIConstantsEx.au3>
#include <WindowsConstants.au3>

$Debug_LB = False ; Проверяет ClassName передаваемый в ListBox функции. Установите True и используйте дескриптор от другого элемента, чтобы увидеть как это работает

_Main()

Func _Main()
    Local $hListBox

    ; Создаёт GUI
    GUICreate("Вставляет пункт в указанную позицию", 400, 296)
    $hListBox = GUICtrlCreateList("", 2, 2, 396, 296, BitOR($WS_BORDER, $LBS_NOTIFY, $LBS_DISABLENOSCROLL, $WS_HSCROLL))
    GUISetState()

    ; Добавляет строки
    _GUICtrlListBox_BeginUpdate($hListBox)
    For $iI = 1 To 9
        _GUICtrlListBox_AddString($hListBox, StringFormat("%03d : Рандомная строка", Random(1, 100, 1)))
    Next
    _GUICtrlListBox_InsertString($hListBox, "Давайте добавим одну длинную строку текста, чтобы получить горизонтальную " & _
        "полосу прокрутки и показать, что, если не обновить полосу прокрутки, то не будет возможности увидеть всю строку.", 4)
    _GUICtrlListBox_UpdateHScroll($hListBox)
    _GUICtrlListBox_EndUpdate($hListBox)

    ; Цикл выполняется, пока окно не будет закрыто
    Do
    Until GUIGetMsg() = $GUI_EVENT_CLOSE
    GUIDelete()
EndFunc   ;==>_Main