Функция _GUICtrlListBox_SetCurSel

         Описание функции

_GUICtrlListBox_SetCurSel

Выбрать пункт и прокрутить его в поле зрения при необходимости

#include <GuiListBox.au3>
_GUICtrlListBox_SetCurSel($hWnd, $iIndex)

Параметры

$hWnd Дескриптор или идентификатор элемента
$iIndex Индекс пункта, отсчёт от 0. Если этот параметр равен -1, то убирается выбор из списка

Возвращаемое значение

Успех:Возвращает True
Ошибка:Возвращает False

Примечания

Используйте эту функцию только в ListBox с одиночным выбором.
Вы не можете использовать эту функцию для удаления выбора в ListBox с множественным выбором.

См. также

_GUICtrlListBox_GetCurSel

Пример

#include <GuiListBox.au3>
#include <GUIConstantsEx.au3>

$Debug_LB = False ; Проверяет ClassName передаваемый в ListBox функции. Установите True и используйте дескриптор от другого элемента, чтобы увидеть как это работает

_Main()

Func _Main()
    Local $hListBox

    ; Создаёт GUI
    GUICreate("Устанавливает выбранный пункт", 400, 296)
    $hListBox = GUICtrlCreateList("", 2, 2, 396, 296)
    GUISetState()

    ; Добавляет строки
    _GUICtrlListBox_BeginUpdate($hListBox)
    For $iI = 1 To 9
        _GUICtrlListBox_AddString($hListBox, StringFormat("%03d : Рандомная строка", Random(1, 100, 1)))
    Next
    _GUICtrlListBox_EndUpdate($hListBox)

    ; Выделяет пункт
    _GUICtrlListBox_SetCurSel($hListBox, 4)

    ; Получает текущий выбранный пункт
    MsgBox(4160, "Информация", "Текущий выбранный пункт: " & _GUICtrlListBox_GetCurSel($hListBox))

    ; Цикл выполняется, пока окно не будет закрыто
    Do
    Until GUIGetMsg() = $GUI_EVENT_CLOSE
    GUIDelete()
EndFunc   ;==>_Main