Функция _GUICtrlHeader_SetItemDisplay

         Описание функции

_GUICtrlHeader_SetItemDisplay

Устанавливает информацию отображения пункта

#include <GuiHeader.au3>
_GUICtrlHeader_SetItemDisplay($hWnd, $iIndex, $iDisplay)

Параметры

$hWnd Дескриптор элемента
$iIndex Индекс пункта, отсчёт от 0
$iDisplay Информация отображения пункта. Может быть комбинацией следующих значений:
    1 - Пункт отображает bitmap
    2 - bitmap находится справа от текста
    4 - Владелец элемента Header рисует пункт
    8 - Пункт отображает строку

Возвращаемое значение

Успех:Возвращает True
Ошибка:Возвращает False

См. также

_GUICtrlHeader_GetItemDisplay, _GUICtrlHeader_SetItemBitmap

Пример

#include <GUIConstantsEx.au3>
#include <GuiHeader.au3>
#include <GuiImageList.au3>
#include <WinAPI.au3>

$Debug_HDR = False ; Проверяет ClassName передаваемый в функции. Установите True и используйте дескриптор от другого элемента, чтобы увидеть как это работает

Global $iMemo

_Main()

Func _Main()
    Local $hGUI, $hHeader, $hImage

    ; Создаёт GUI
    $hGUI = GUICreate(StringTrimRight(@ScriptName, 4), 400, 300)
    $hHeader = _GUICtrlHeader_Create ($hGUI)
    _GUICtrlHeader_SetUnicodeFormat ($hHeader, True)
    $iMemo = GUICtrlCreateEdit("", 2, 24, 396, 274, 0)
    GUICtrlSetFont($iMemo, 9, 400, 0, "Courier New")
    GUISetState()

    ; Создаёт список изображений с изображениями
    $hImage = _GUIImageList_Create (11, 11)
    _GUIImageList_Add ($hImage, _WinAPI_CreateSolidBitmap ($hGUI, 0xFF0000, 11, 11))
    _GUIImageList_Add ($hImage, _WinAPI_CreateSolidBitmap ($hGUI, 0x00FF00, 11, 11))
    _GUIImageList_Add ($hImage, _WinAPI_CreateSolidBitmap ($hGUI, 0x0000FF, 11, 11))
    _GUICtrlHeader_SetImageList ($hHeader, $hImage)

    ; Добавляет колонки
    _GUICtrlHeader_AddItem ($hHeader, "Колонка 1", 100, 0)
    _GUICtrlHeader_AddItem ($hHeader, "Колонка 2", 100, 0, 1)
    _GUICtrlHeader_AddItem ($hHeader, "Колонка 3", 100, 0, 2)
    _GUICtrlHeader_AddItem ($hHeader, "Колонка 4", 100)

    ; Устанавливает bitmap 1-ой колонки
    _GUICtrlHeader_SetItemBitmap ($hHeader, 0, _WinAPI_CreateSolidBitmap ($hGUI, 0xFF00FF, 11, 11))

    ; Устанавливает информацию отображения 1-ой колонки
    _GUICtrlHeader_SetItemDisplay ($hHeader, 0, 1 + 2 + 8)

    ; Показывает информацию отображения 1-ой колонки
    MemoWrite("Информация отображения 1-ой колонки: " & _GUICtrlHeader_GetItemDisplay ($hHeader, 0))

    ; Цикл выполняется, пока окно не будет закрыто
    Do
    Until GUIGetMsg() = $GUI_EVENT_CLOSE
EndFunc   ;==>_Main

; Записывает строку в элемент для заметок
Func MemoWrite($sMessage)
    GUICtrlSetData($iMemo, $sMessage & @CRLF, 1)
EndFunc   ;==>MemoWrite