Функция _GUICtrlHeader_SetItemBitmap

         Описание функции

_GUICtrlHeader_SetItemBitmap

Устанавливает дескриптор bitmap пункта

#include <GuiHeader.au3>
_GUICtrlHeader_SetItemBitmap($hWnd, $iIndex, $hBmp)

Параметры

$hWnd Дескриптор элемента
$iIndex Индекс пункта, отсчёт от 0
$hBmp Дескриптор bitmap пункта

Возвращаемое значение

Успех:Возвращает True
Ошибка:Возвращает False

Примечания

После вызова этой функции, убедитесь, что вы вызвали _GUICtrlHeader_SetItemDisplay для установки информации отображения пункта.

См. также

_GUICtrlHeader_GetItemBitmap, _GUICtrlHeader_SetItemDisplay

Пример

#include <GUIConstantsEx.au3>
#include <GuiHeader.au3>
#include <GuiImageList.au3>
#include <WinAPI.au3>

$Debug_HDR = False ; Проверяет ClassName передаваемый в функции. Установите True и используйте дескриптор от другого элемента, чтобы увидеть как это работает

Global $iMemo

_Main()

Func _Main()
    Local $hGUI, $hHeader, $hImage

    ; Создаёт GUI
    $hGUI = GUICreate(StringTrimRight(@ScriptName, 4), 400, 300)
    $hHeader = _GUICtrlHeader_Create ($hGUI)
    _GUICtrlHeader_SetUnicodeFormat ($hHeader, True)
    $iMemo = GUICtrlCreateEdit("", 2, 24, 396, 274, 0)
    GUICtrlSetFont($iMemo, 9, 400, 0, "Courier New")
    GUISetState()

    ; Создаёт список изображений с изображениями
    $hImage = _GUIImageList_Create (11, 11)
    _GUIImageList_Add ($hImage, _WinAPI_CreateSolidBitmap ($hGUI, 0xFF0000, 11, 11))
    _GUIImageList_Add ($hImage, _WinAPI_CreateSolidBitmap ($hGUI, 0x00FF00, 11, 11))
    _GUIImageList_Add ($hImage, _WinAPI_CreateSolidBitmap ($hGUI, 0x0000FF, 11, 11))
    _GUICtrlHeader_SetImageList ($hHeader, $hImage)

    ; Добавляет колонки
    _GUICtrlHeader_AddItem ($hHeader, "Колонка 1", 100, 0, 0)
    _GUICtrlHeader_AddItem ($hHeader, "Колонка 2", 100, 0, 1)
    _GUICtrlHeader_AddItem ($hHeader, "Колонка 3", 100, 0, 2)
    _GUICtrlHeader_AddItem ($hHeader, "Колонка 4", 100)

    ; Устанавливает bitmap 4-ой колонки
    _GUICtrlHeader_SetItemBitmap ($hHeader, 3, _WinAPI_CreateSolidBitmap ($hGUI, 0xFF00FF, 11, 11))
    _GUICtrlHeader_SetItemDisplay ($hHeader, 3, 1 + 8)

    ; Показывает дескриптор bitmap 4-ой колонки
    MemoWrite("Дескриптор bitmap 4-ой колонки: " & "0x" & Hex(_GUICtrlHeader_GetItemBitmap ($hHeader, 3)))

    ; Цикл выполняется, пока окно не будет закрыто
    Do
    Until GUIGetMsg() = $GUI_EVENT_CLOSE
EndFunc   ;==>_Main

; Записывает строку в элемент для заметок
Func MemoWrite($sMessage)
    GUICtrlSetData($iMemo, $sMessage & @CRLF, 1)
EndFunc   ;==>MemoWrite