Функция _GUICtrlDTP_GetSystemTime

         Описание функции

_GUICtrlDTP_GetSystemTime

Возвращает выбранную дату и время

#include <GuiDateTimePicker.au3>
_GUICtrlDTP_GetSystemTime($hWnd)

Параметры

$hWnd Дескриптор элемента

Возвращаемое значение

Успех: Возвращает массив следующего формата:

    [0] - год
    [1] - месяц
    [2] - день
    [3] - час
    [4] - минута
    [5] - секунда

Примечания

@error может иметь значения:
$GDT_VALID, если информация о времени была успешно возвращена.
$GDT_NONE, если элемент имеет стиль $DTS_SHOWNONE и галочка не была установлена.
$GDT_ERROR, если произошла ошибка.

См. также

_GUICtrlDTP_SetSystemTime, _GUICtrlDTP_GetSystemTimeEx

Пример

#include <GUIConstantsEx.au3>
#include <GuiDateTimePicker.au3>

$Debug_DTP = False ; Проверяет ClassName передаваемый в DTP функции. Установите True и используйте дескриптор от другого элемента, чтобы увидеть как это работает

Global $iMemo, $tRange, $aDate

_Main()

Func _Main()
    Local $hDTP, $a_Date[7] = [False, @YEAR, 8, 19, 21, 57, 34]

    ; Создаёт GUI
    GUICreate("Получает дату и время", 400, 300)
    $hDTP = GUICtrlGetHandle(GUICtrlCreateDate("", 2, 6, 190))
    $iMemo = GUICtrlCreateEdit("", 2, 32, 396, 266, 0)
    GUICtrlSetFont($iMemo, 9, 400, 0, "Courier New")
    GUISetState()

    ; Устанавливает формат строки
    _GUICtrlDTP_SetFormat($hDTP, "ddd MMM dd, yyyy hh:mm ttt")

    ; Устанавливает дату и время
    _GUICtrlDTP_SetSystemTime($hDTP, $a_Date)

    ; Получает дату и время
    $aDate = _GUICtrlDTP_GetSystemTime($hDTP)
    MemoWrite("Выбранная дата : " & GetDateStr())
    MemoWrite("Выбранное время: " & GetTimeStr())

    ; Цикл выполняется, пока окно не будет закрыто
    Do
    Until GUIGetMsg() = $GUI_EVENT_CLOSE
    GUIDelete()
EndFunc   ;==>_Main

; Возвращает элементы даты
Func GetDateStr()
    Return StringFormat("%02d/%02d/%04d", $aDate[1], $aDate[2], $aDate[0])
EndFunc   ;==>GetDateStr

; Возвращает элементы времени
Func GetTimeStr()
    Return StringFormat("%02d:%02d:%02d", $aDate[3], $aDate[4], $aDate[5])
EndFunc   ;==>GetTimeStr

; Записывает строку в элемент для заметок
Func MemoWrite($sMessage)
    GUICtrlSetData($iMemo, $sMessage & @CRLF, 1)
EndFunc   ;==>MemoWrite